'########################################
'#                                      #
'#              MAIN SCRIPT             #
'#                                      #
'#    MAN Standarddoppeldecker SD200    #
'#                                      #
'#             Bauart SD85              #
'#                                      #
'########################################

'(c) 01.11.2012 Marcel Kuhnt, Rüdiger Hülsmann

'Script Version: 1.0
'Omsi release: 1.0


'Revision History:
'- Marcel Kuhnt		10.08.2009	Added Revision History
'- Marcel Kuhnt		30.11.2010	Bugfix: press [D] in AI mode if motor running but neutral
'- Marcel Kuhnt		04.07.2011	Added light repair
'- Marcel Kuhnt		11.12.2012	Added elec repair

'------------------------------------------------------------------------------------------


'######################
'	Hauptteil
'######################

{init}
	(M.L.engine_Init)
	(M.L.Antrieb_Init)
	(M.L.Elec_Init)
	(M.L.Door_Init)
	(M.L.wiper_init)
	(M.L.lights_init)
	(M.L.bremse_init)
'	(M.L.rollband_init)
	(M.L.cockpit_init)
	(M.L.heizung_init)
	(M.L.Matrix_init)
	(M.L.IBIS_init)
	(M.L.Collision_Init)
'	(M.L.ticketprinter_init)
	(M.L.articulation_init)
	(M.L.VDV_init)
	(M.L.Innenanzeige_multi_init)
	(M.L.ramplift_init)
	(M.L.EVENDPC2_init)
	(M.L.IBISPlus_init)
	(M.L.EFAD_init)
	3 random s0
	"Werbung\Werbung_" l0 $IntToStr $+ ".dds" $+ (S.$.Werbung)
{end}

{frame}
	(M.L.Engine_Frame)
	(M.L.Antrieb_Frame)
	(M.L.Elec_Frame)
	(M.L.Door_frame)
	(M.L.cockpit_frame)
	(M.L.lights_frame)
	(M.L.wiper_frame)
	(M.L.Auspuff_Frame)
	(M.L.bremse_frame)
	(M.L.klappern_frame)
	(M.L.FF_frame)
	(M.L.rain_frame)
	(M.L.dirt_frame)
	(M.L.sound_volume_frame)
	(M.L.heizung_frame)
	(M.L.IBIS_frame)
	(M.L.Matrix_frame)
	(M.L.cashdesk_frame)
	(M.L.Collision_Frame)
	(M.L.articulation_frame)
	(M.L.wackeln_y)
	(M.L.spray_frame)
	(M.L.VDV_frame)
	(M.L.Innenanzeige_multi_frame)
	(M.L.ramplift_frame)
	(M.L.EVENDPC2_frame)
	(M.L.IBISPlus_frame)
	(M.L.EFAD_frame)
	(M.L.wimpel_frame)
	(M.L.RBL_Frame)
	0 (M.V.GetDepotStringGlobal) "HB_Bremen_2018" $=
	0 (M.V.GetDepotStringGlobal) "HB_Bremen_2016" $= ||
	0 (M.V.GetDepotStringGlobal) "HB_Bremen_2010" $= ||
	{if}
		(L.$.ident) 4 $cutEnd (L.$.Number) 1 $cutBegin $+ (S.$.ident_2)
	{else}
		(L.$.ident) (S.$.ident_2)
	{endif}
	(L.L.Colorscheme) -1 =
	(L.L.vis_IBIS_Version_int) ! &&
	(L.L.vis_printer_version_int) ! &&
	(L.L.CTI_switched) ! &&
	{if}
		1 (S.L.vis_IBIS_Version_int) (S.L.vis_printer_version_int)
	{endif}
	(L.L.CTI_switched) !
	(L.L.Colorscheme) -1 = ! &&
	{if}
		(L.L.vis_IBIS_Version) (S.L.vis_IBIS_Version_int)
		(L.L.vis_printer_version) (S.L.vis_printer_version_int)
		(L.L.vis_hubcap_v) (S.L.vis_hubcap_v_int)
		(L.L.vis_hubcap_m) (S.L.vis_hubcap_m_int)
		(L.L.vis_hubcap_h) (S.L.vis_hubcap_h_int)
		(L.L.vis_clima) (S.L.vis_clima_int)
		(L.L.vis_clima_h) (S.L.vis_clima_h_int)
		(L.L.vis_haltefaden) (S.L.vis_haltefaden_int)
		(L.L.vis_Innenanzeige) (S.L.vis_Innenanzeige_int)
		(L.L.vis_Matrixtype) (S.L.vis_Matrixtype_int)
		(L.L.vis_doortype_v) (S.L.vis_doortype_v_int)
		(L.L.vis_doortype_m) (S.L.vis_doortype_m_int)
		(L.L.vis_doortype_h) (S.L.vis_doortype_h_int)
		(L.L.vis_Wagennummer) (S.L.vis_Wagennummer_int)
		(L.L.vis_Zusatzspiegel) (S.L.vis_Zusatzspiegel_int)
	{endif}
	(L.L.vis_printer_version_int) 2 =
	{if}
		1 (S.L.Daueranimation_Drucker)
	{else}
		0 (S.L.Daueranimation_Drucker)
		0 (S.L.zahltisch)
	{endif}

	
'	Klappsitz durch Fahrgast
	1 (M.V.GetHumanCountOnSeat) (S.L.klappsitz_1)
	2 (M.V.GetHumanCountOnSeat) (S.L.klappsitz_2)
	3 (M.V.GetHumanCountOnSeat) (S.L.klappsitz_3)
'	Kennzeichengröße

	(L.$.ident) $length 10 >
	{if}
		1 (S.L.kennzeichengroesse)
	{else}
		0 (S.L.kennzeichengroesse)
	{endif}

	(L.L.vis_doortype_v_int) 0 =
	{if}
		0 (S.L.LC_Rampe_visible)
	{else}
		1 (S.L.LC_Rampe_visible)
	{endif}
'...............................
'AI:

	(L.L.AI_Engine) 0.5 >
	(L.L.engine_on) 0.5 <
	(L.L.antrieb_getr_gangvorwahl) 4 = ! ||
	&&
	{if}
		0 (S.L.bremse_feststell_sw) (S.L.bremse_feststell)
		1 (S.L.engine_injection_on) (S.L.elec_busbar_main_sw)
		400 (S.L.engine_n)
		4 (S.L.antrieb_getr_gangvorwahl)
		1 (S.L.engine_on) (S.L.vdv_on) (S.L.cp_key_pull)
		3 (S.L.key_mode)
		0.4 (S.L.cp_key_rot)
		900000 (S.L.bremse_p_tank01) (S.L.bremse_p_tank02) (S.L.bremse_p_tank03) (S.L.bremse_p_tank04) (S.L.bremse_p_leitung01) (S.L.bremse_p_leitung02)
		400000 (S.L.bremse_p_balg_0_R) (S.L.bremse_p_balg_0_L) (S.L.bremse_p_balg_1_R) (S.L.bremse_p_balg_1_L) 
	{endif}

	(L.L.AI_Engine) -0.5 <
	(L.L.engine_on) 0.5 >
	&&
	{if}
		0 (S.L.engine_on)
		0 (S.L.engine_injection_on)
		1 (S.L.bremse_feststell_sw) (S.L.bremse_feststell)
		2 (S.L.key_mode)
		0.2 (S.L.cp_key_rot)
	{endif}

	(L.L.AI)
	{if}
		(L.L.Brake) (C.L.max_bremskraft) * (S.L.Brakeforce)
		1 (S.L.elec_busbar_main)
		(S.L.elec_busbar_avail)
	{endif}

{end}

'----------------------------------
'Crash:

{trigger:collision}
	(M.L.Collision_Trigger)
{end}


'----------------------------------
'malfunction reset:


{trigger:malfunction_reset}
	(M.L.Collision_Malfunction_Reset)
	(M.L.Elec_Malfunction_Reset)
{end}


'----------------------------------
'malfunction time calc:

{trigger:malfunction_gettime}
	0 s0
	(M.L.Collision_Malfunction_TimeCalc)
	(M.L.Elec_Malfunction_TimeCalc)
{end}

{macro:wimpel_frame}
	(L.S.Day) s0
	(L.S.Month) s1
	l0 03 = l1 10 = &&
	l0 18 = l1 10 = && ||
	l0 19 = l1 10 = && ||
	l0 20 = l1 10 = && ||
	l0 21 = l1 10 = && ||
	l0 22 = l1 10 = && ||
	l0 23 = l1 10 = && ||
	l0 24 = l1 10 = && ||
	l0 25 = l1 10 = && ||
	l0 26 = l1 10 = && ||
	l0 27 = l1 10 = && ||
	l0 28 = l1 10 = && ||
	l0 29 = l1 10 = && ||
	l0 30 = l1 10 = && ||
	l0 31 = l1 10 = && ||
	l0 01 = l1 11 = && ||
	l0 02 = l1 11 = && ||
	l0 03 = l1 11 = && ||
	(S.L.wimpel_visibility)
{end}