'###################################################################################################

'DGM-Modul Mobitec Ziel

'Beinhaltet sämtliche Mobitec-spezifischen Scriptteile für Mobitec-Anzeigen.
'(Fonts, Zieltextpostitionen, Setvars, allg. Fontfindung)
'###################################################################################################
{macro:Matrix_Mobi_Fonts}
	"Mobi_Ziel7_3" (M.V.GetFontIndex) (S.L.Font_7_2)
	"Mobi_Ziel7_2" (M.V.GetFontIndex) (S.L.Font_7_1)
	"Mobi_Ziel7" (M.V.GetFontIndex) (S.L.Font_8)
	"Mobi_Ziel9" (M.V.GetFontIndex) (S.L.Font_12)
	"Mobi_Ziel13x6_Post" (M.V.GetFontIndex) (S.L.Font_13x6_Post)
	"Mobi_Ziel13" (M.V.GetFontIndex) (S.L.Font_13)
	"Mobi_Ziel17" (M.V.GetFontIndex) (S.L.Font_18)
	"Mobi_Ziel16x9" (M.V.GetFontIndex) (S.L.Font_16x9_Mobi)
	"Mobi_Ziel24" (M.V.GetFontIndex) (S.L.Font_24)
	"Mobi_Ziel24U" (M.V.GetFontIndex) (S.L.Font_24U)
	"Wien Lawo Symbols 26" (M.V.GetFontIndex) (S.L.Font_Symbols26)

	(L.L.vis_Linie_KMG) ! {if} "Mobi_Linie24" {else} "Mobi_Linie24_KMG" {endif}
	(M.V.GetFontIndex) (S.L.Font_26x14)
	"Mobi_Linie16" (M.V.GetFontIndex) (S.L.Font_26x12)
	"Mobi_Linie16x6" (M.V.GetFontIndex) (S.L.Font_Linie16x6_Mobi)
{end}
'###################################################################################################
{macro:Matrix_Ziel1z_Mobi16}
	0 (S.L.Matrix_Ypos)
	(L.$.Matrix_TerminusL1) (L.L.Font_16x9_Mobi) s1 (M.V.TextLength) s2 l0 >
	(L.L.vis_Font_Post) 2 < ||
	{if}
		(L.$.Matrix_TerminusL1) (L.L.Font_13) s1 (M.V.TextLength) s2 l0 >
		{if}
			(L.$.Matrix_TerminusL1) (L.L.Font_18) s1 (M.V.TextLength) s2 l0 >
			(L.L.Matrix_TerminusL1HasDescender) ||
			{if}
				(L.$.Matrix_TerminusL1) (L.L.Font_13x6_Post) s1 (M.V.TextLength) s2 l0 >
				(L.L.vis_Font_Post) ! ||
				{if}
					(L.$.Matrix_TerminusL1) (L.L.Font_12) s1 (M.V.TextLength) s2 l0 >
					{if}
						(L.$.Matrix_TerminusL1) (L.L.Font_8) s1 (M.V.TextLength) s2 l0 >
						{if}
							(L.$.Matrix_TerminusL1) (L.L.Font_7_1) s1 (M.V.TextLength) s2 l0 >
							{if}							
								(L.$.Matrix_TerminusL1) (L.L.Font_7_2) s1 (M.V.TextLength) s2
							{endif}
						{endif}	
						4 (S.L.Matrix_Ypos)							
					{else}
						3 (S.L.Matrix_Ypos)
					{endif}
				{endif}					
			{endif}
		{endif}
	{endif}
	2 (S.L.Matrix_Sperrung)
{end}
'###################################################################################################

{macro:Matrix_Ziel1z_Mobi24}
	(L.$.Matrix_TerminusL1) (L.L.Font_24) s1 (M.V.TextLength) s2 l0 >
	(L.L.vis_Font_Post) 2 = (L.L.Matrix_TerminusL1HasDescender) && ||
	{if}
	(L.$.Matrix_TerminusL1) (L.L.Font_24U) s1 (M.V.TextLength) s2 l0 >
	(L.L.vis_Font_Post) 2 < ||
	{if}
		(L.$.Matrix_TerminusL1) (L.L.Font_18) s1 (M.V.TextLength) s2 l0 >
		{if}
			(L.$.Matrix_TerminusL1) (L.L.Font_13) s1 (M.V.TextLength) s2 l0 >
			{if}
				(L.$.Matrix_TerminusL1) (L.L.Font_16x9_Mobi) s1 (M.V.TextLength) s2 l0 >
				(L.L.vis_Font_Post) 2 < ||
				{if}				
					(L.$.Matrix_TerminusL1) (L.L.Font_13x6_Post) s1 (M.V.TextLength) s2 l0 >
					(L.L.vis_Font_Post) ! ||
					{if}						
						(L.$.Matrix_TerminusL1) (L.L.Font_12) s1 (M.V.TextLength) s2 l0 >
						{if}
							(L.$.Matrix_TerminusL1) (L.L.Font_8) s1 (M.V.TextLength) s2 l0 >
							{if}
								(L.$.Matrix_TerminusL1) (L.L.Font_7_1) s1 (M.V.TextLength) s2 l0 >
								{if}							
									(L.$.Matrix_TerminusL1) (L.L.Font_7_2) s1 (M.V.TextLength) s2
								{endif}
							{endif}	
							6 (S.L.Matrix_Ypos)							
						{else}
							3 (S.L.Matrix_Ypos)
						{endif}
					{else}
						3 (S.L.Matrix_Ypos)
					{endif}
				{else}
					3 (S.L.Matrix_Ypos)
				{endif}
			{else}
				3 (S.L.Matrix_Ypos)
			{endif}
		{else}
			2 (S.L.Matrix_Ypos)
		{endif}
	{else}
		0 (S.L.Matrix_Ypos)	
	{endif}
	{else}
		0 (S.L.Matrix_Ypos)
	{endif}
	(L.L.Matrix_Height) 26 = {if} 3 (S.L.Matrix_Sperrung) {else} 2 (S.L.Matrix_Sperrung) {endif}
	(L.L.matrix_invertMode) 2 % 1 = (L.L.Matrix_Height) 26 = && {if} (L.L.Matrix_Ypos) 1 + (S.L.Matrix_Ypos) {endif}
{end}
'###################################################################################################
{macro:Matrix_Ziel2z_Mobi16z1}
'Zeile 1, ohne Parameter:
	(L.$.Matrix_TerminusL1) (L.L.Font_7_1) s1 (M.V.TextLength) s2 l0 >
	{if}
		(L.$.Matrix_TerminusL1) (L.L.Font_7_2) s1 (M.V.TextLength) s2
	{endif}
'Das Zeugs mit *K und *B; kommt erst nach dem eigentlichen Teil ohne große if-Abfrage, weil ich faul bin.
	(L.L.matrix_BoldMode) 10 =
	{if}
		(L.$.Matrix_TerminusL1) (L.L.Font_7_2) s1 (M.V.TextLength) s2					
	{endif}

	(L.L.matrix_BoldMode) 11 =
	{if}
		(L.$.Matrix_TerminusL1) (L.L.Font_8) s1 (M.V.TextLength) s2 l0 >
		{if}
			(L.$.Matrix_TerminusL1) (L.L.Font_7_1) s1 (M.V.TextLength) s2
		{endif}
	{endif}	
	2 (S.L.Matrix_Sperrung)
{end}

'###################################################################################################

{macro:Matrix_Ziel2z_Mobi24z1}
'Erster Font: 13px für 26px Matrix, danach Hättenschweiler, wenn 26px und Font aktiv, sonst normal weiter.
	(L.$.Matrix_TerminusL1) (L.L.Font_13) s1 (M.V.TextLength) s2 l0 >
	(L.L.Matrix_Height) 26 < ||
	{if}
		(L.$.Matrix_TerminusL1) (L.L.Font_16x9_Mobi) s1 (M.V.TextLength) s2 l0 >
		(L.L.Matrix_Height) 26 < ||
		(L.L.vis_Font_Post) 2 < ||
		{if}
			(L.$.Matrix_TerminusL1) (L.L.Font_13x6_Post) s1 (M.V.TextLength) s2 l0 >
			(L.L.Matrix_Height) 26 < ||
			(L.L.vis_Font_Post) ! ||
			{if}
				0 s7
				(L.$.Matrix_TerminusL1) (L.L.Font_12) s1 (M.V.TextLength) s2 l0 >
				{if}
					(L.$.Matrix_TerminusL1) (L.L.Font_8) s1 (M.V.TextLength) s2 l0 >
					{if}
						(L.$.Matrix_TerminusL1) (L.L.Font_7_1) s1 (M.V.TextLength) s2 l0 >
						{if}
							(L.$.Matrix_TerminusL1) (L.L.Font_7_2) s1 (M.V.TextLength) s2
						{endif}
						3 (S.L.Matrix_Ypos)
					{else}
						2 (S.L.Matrix_Ypos)
					{endif}
				{else}
					0 (S.L.Matrix_Ypos)
				{endif}
			{endif}
		{endif}
	{endif}
	l7 (S.L.matrix_temp)
'Das Zeugs mit *K und *B; kommt erst nach dem eigentlichen Teil ohne große if-Abfrage, weil ich faul bin.
			
	(L.L.matrix_BoldMode) 10 =
	{if}
		(L.$.Matrix_TerminusL1) (L.L.Font_7_1) s1 (M.V.TextLength) s2 l0 >
		{if}
			(L.$.Matrix_TerminusL1) (L.L.Font_7_1) s1 (M.V.TextLength) s2
		{endif}
		0 (S.L.Matrix_Ypos)			
	{endif}
		(L.L.matrix_BoldMode) 11 =
	{if}
		(L.$.Matrix_TerminusL1) (L.L.Font_18) s1 (M.V.TextLength) s2 l0 >
		(L.L.Matrix_Height) 26 < ||
		{if}
			(L.$.Matrix_TerminusL1) (L.L.Font_13) s1 (M.V.TextLength) s2 l0 >
			{if}
				(L.$.Matrix_TerminusL1) (L.L.Font_16x9_Mobi) s1 (M.V.TextLength) s2 l0 >
				(L.L.vis_Font_Post) 2 < ||
				{if}			
					(L.$.Matrix_TerminusL1) (L.L.Font_13x6_Post) s1 (M.V.TextLength) s2 l0 >
					(L.L.vis_Font_Post) ! ||
					{if}
						(L.$.Matrix_TerminusL1) (L.L.Font_12) s1 (M.V.TextLength) s2
						3 (S.L.Matrix_Ypos)
					{else}
						0 (S.L.Matrix_Ypos)
					{endif}
				{else}
					0 (S.L.Matrix_Ypos)
				{endif}
			{else}
				0 (S.L.Matrix_Ypos)
			{endif}
		{endif}
	{endif}	

	(L.L.Matrix_Height) 26 = {if} 3 (S.L.Matrix_Sperrung) {else} 2 (S.L.Matrix_Sperrung) {endif}
{end}
'###################################################################################################
{macro:Matrix_Ziel2z_Mobi16z2}
	(L.$.Matrix_TerminusL2) (L.L.Font_7_1) s1 (M.V.TextLength) s2 l0 >
	{if}
		(L.$.Matrix_TerminusL2) (L.L.Font_7_2) s1 (M.V.TextLength) s2
		9 (S.L.Matrix_Ypos)			
	{else}
		8 (S.L.Matrix_Ypos)				
	{endif}
	(L.L.matrix_BoldMode) 11 =
	{if}
		(L.$.Matrix_TerminusL2) (L.L.Font_7_2) s1 (M.V.TextLength) s2			
		9 (S.L.Matrix_Ypos)			
	{endif}

	(L.L.matrix_BoldMode) 10 =
	{if}
		(L.$.Matrix_TerminusL2) (L.L.Font_8) s1 (M.V.TextLength) s2 l0 >
		{if}
			(L.$.Matrix_TerminusL2) (L.L.Font_7_1) s1 (M.V.TextLength) s2
			8 (S.L.Matrix_Ypos)						
		{else}
			7 (S.L.Matrix_Ypos)					
		{endif}	
	{endif}
	2 (S.L.Matrix_Sperrung)
{end}

'###################################################################################################
{macro:Matrix_Ziel2z_Mobi24z2}
	(L.$.Matrix_TerminusL2) (L.L.Font_12) s1 (M.V.TextLength) s2 l0 >
	{if}
		(L.$.Matrix_TerminusL2) (L.L.Font_8) s1 (M.V.TextLength) s2 l0 >
		{if}
			(L.$.Matrix_TerminusL2) (L.L.Font_7_1) s1 (M.V.TextLength) s2 l0 >
			{if}
				(L.$.Matrix_TerminusL2) (L.L.Font_7_2) s1 (M.V.TextLength) s2
			{endif}	
			17 (S.L.Matrix_Ypos)
		{else}
			15 (S.L.Matrix_Ypos)
		{endif}
	{else}
		13 1 + (S.L.Matrix_Ypos)
	{endif}
	(L.L.Matrix_Height) 26 < {if} 13 (S.L.Matrix_Ypos) {endif}
	
	(L.L.matrix_BoldMode) 11 =
	{if}
		(L.$.Matrix_TerminusL2) (L.L.Font_7_1) s1 (M.V.TextLength) s2 l0 >
		{if}
			(L.$.Matrix_TerminusL2) (L.L.Font_7_1) s1 (M.V.TextLength) s2
		{endif}
		(L.L.Matrix_Height) 26 = {if} 18 {else} 16 {endif} (S.L.Matrix_Ypos)			
	{endif}

	(L.L.matrix_BoldMode) 10 =
	{if}
		(L.$.Matrix_TerminusL2) (L.L.Font_18) s1 (M.V.TextLength) s2 l0 >
		(L.L.Matrix_Height) 26 < ||
		(L.L.Matrix_TerminusL2HasDescender) ||
		{if}
			(L.$.Matrix_TerminusL2) (L.L.Font_13) s1 (M.V.TextLength) s2 l0 >
			{if}
				(L.$.Matrix_TerminusL2) (L.L.Font_16x9_Mobi) s1 (M.V.TextLength) s2 l0 >
				(L.L.vis_Font_Post) 2 < ||
				{if}			
					(L.$.Matrix_TerminusL2) (L.L.Font_13x6_Post) s1 (M.V.TextLength) s2 l0 >
					(L.L.vis_Font_Post) ! ||
					{if}
						(L.$.Matrix_TerminusL2) (L.L.Font_12) s1 (M.V.TextLength) s2
					{endif}
				{endif}
			{endif}
			(L.L.Matrix_Height) 26 = 9 + (S.L.Matrix_Ypos)
		{else}
			9 (S.L.Matrix_Ypos)
		{endif}
	{endif}
	(L.L.Matrix_Height) 26 = {if} 3 (S.L.Matrix_Sperrung) {else} 2 (S.L.Matrix_Sperrung) {endif}
{end}