'##############
' IBIS KVB
'##############

' 2018 Darius Bode

'----------------------
'	Trigger
'----------------------

{trigger:cp_microphone}  
	(L.L.ibis_stopcount) 0 >
	(L.L.ibis_stop_adv_lock) ! &&
		{if}
			(L.L.ibis_stop) (L.L.ibis_stopcount) 1 - < &&
				{if}
					(L.L.ibis_stop) 1 + (S.L.ibis_stop)
				{else}
					0 (S.L.ibis_stop)					
				{endif}
		{endif}
	1 (S.L.ibis_stop_adv_lock)
{end}

{trigger:cp_microphone_off}	
	0 (S.L.ibis_stop_adv_lock)
{end}

{trigger:ibis_sw_fortschaltung}	
	1 (S.L.ibis_sw_fortschaltung)
	(T.L.ev_wippschaltereinsound)		
{end}

{trigger:ibis_sw_fortschaltung_off}
	0 (S.L.ibis_sw_fortschaltung) (S.L.ibis_stop_adv_lock)
	(T.L.ev_wippschalteraussound)
{end}

{trigger:ibis_klickU1}

	(T.L.ev_ibis_taste)
	(L.L.ibis_an) (S.L.ibis_klickU1)
	
{end}

{trigger:ibis_klickU2}

	(T.L.ev_ibis_taste)
	(L.L.ibis_an) (S.L.ibis_klickU2)
	
{end}

{trigger:ibis_klickU3}

	(T.L.ev_ibis_taste)
	(L.L.ibis_an) (S.L.ibis_klickU3)
	
{end}

{trigger:ibis_klickU4}

	(T.L.ev_ibis_taste)
	(L.L.ibis_an) (S.L.ibis_klickU4)
	
{end}

{trigger:ibis_klickU5}

	(T.L.ev_ibis_taste)
	(L.L.ibis_an) (S.L.ibis_klickU5)
	
{end}

{trigger:ibis_klickR1}

	(T.L.ev_ibis_taste)
	(L.L.ibis_an) (S.L.ibis_klickR1)
	
{end}

{trigger:ibis_klickR2}

	(T.L.ev_ibis_taste)
	(L.L.ibis_an) (S.L.ibis_klickR2)
	
{end}

{trigger:ibis_klickR3}

	(T.L.ev_ibis_taste)
	(L.L.ibis_an) (S.L.ibis_klickR3)
	
{end}

{trigger:ibis_klickR4}

	(T.L.ev_ibis_taste)
	(L.L.ibis_an) (S.L.ibis_klickR4)
	
{end}

{trigger:ibis_klickNenter}

	(T.L.ev_ibis_taste)
	(L.L.ibis_an) (S.L.ibis_klickNenter)
	
{end}

{trigger:ibis_klickNesc}

	(T.L.ev_ibis_taste)
	(L.L.ibis_an) (S.L.ibis_klickNesc)
	
{end}

{trigger:ibis_klickNhoch}

	(T.L.ev_ibis_taste)
	(L.L.ibis_an) (S.L.ibis_klickNhoch)
	
{end}

{trigger:ibis_klickN0}

	(T.L.ev_ibis_taste)
	(L.L.ibis_an) (S.L.ibis_klickN0)
	
{end}

{trigger:ibis_klickN1}

	(T.L.ev_ibis_taste)
	(L.L.ibis_an) (S.L.ibis_klickN1)
	
{end}

{trigger:ibis_klickN2}

	(T.L.ev_ibis_taste)
	(L.L.ibis_an) (S.L.ibis_klickN2)
	
{end}

{trigger:ibis_klickN3}

	(T.L.ev_ibis_taste)
	(L.L.ibis_an) (S.L.ibis_klickN3)
	
{end}

{trigger:ibis_klickN4}

	(T.L.ev_ibis_taste)
	(L.L.ibis_an) (S.L.ibis_klickN4)
	
{end}

{trigger:ibis_klickN5}

	(T.L.ev_ibis_taste)
	(L.L.ibis_an) (S.L.ibis_klickN5)
	
{end}

{trigger:ibis_klickN6}

	(T.L.ev_ibis_taste)
	(L.L.ibis_an) (S.L.ibis_klickN6)
	
{end}

{trigger:ibis_klickN7}

	(T.L.ev_ibis_taste)
	(L.L.ibis_an) (S.L.ibis_klickN7)
	
{end}

{trigger:ibis_klickN8}

	(T.L.ev_ibis_taste)
	(L.L.ibis_an) (S.L.ibis_klickN8)
	
{end}

{trigger:ibis_klickN9}

	(T.L.ev_ibis_taste)
	(L.L.ibis_an) (S.L.ibis_klickN9)
	
{end}


{macro:ibis_init}

	-1 (S.L.ibis_display)
	-1 (S.L.int_routeindex)
	
{end}


'----------------------
'	Frame
'----------------------

' ############# MENÜSEITEN
' -1 = aus
' 0 = leer
' 1 = Hochfahren
' 2 = Anmeldung Linie
' 3 = Anmeldung Kurs
' 4 = Relativer Fahrplan
' 5 = Ziel/Sonderziel
' 6 = Menü
' 7 = Selbsthaltung
' 8 = Abmeldung
' 9 = Fehler Li/Krs unbekannt

{macro:ibis_frame}

(L.L.AI) !
	{if}
	
		1 (S.L.Refresh_Strings)

'		Aus wenn kein Strom		
		(L.L.elec_V_battery) (C.L.elec_busbar_Vmin) <
			{if}
				(M.L.ibis_aus)
			{endif}

'		Hochfahren			
		(L.L.ibis_an) !
			{if}
			
				(L.L.elec_busbar_main) 
					{if}
						1 (S.L.ibis_an)
						0 (S.L.ibis_starttimer)
						-1 (S.L.ibis_display)
						"" (S.$.input) "" (S.$.zeile_delay) (S.$.ibis_innenanz)
					{endif}
					
			{else}

' ############# STARTSEQUENZ	
		
				(L.L.ibis_starttimer) 9 <=
					{if}					
						(L.L.ibis_starttimer) (L.S.Timegap) + (S.L.ibis_starttimer)
						
						(L.L.ibis_starttimer) 2 >
						(L.L.ibis_starttimer) 6 <= &&
							{if}
								0 (S.L.ibis_display) (S.L.ibis_display_req)		
							{endif}
							
						(L.L.ibis_starttimer) 6 >
						(L.L.ibis_starttimer) 8 <= &&
							{if}
								1 (S.L.ibis_display) (S.L.ibis_display_req)			
							{endif}
							
						(L.L.ibis_starttimer) 8 >
							{if}
								2 (S.L.ibis_display_req)
							{endif}
							
						
						"" (S.$.zeile_delay) (S.$.ibis_innenanz)
						
					{else}
					
					
' ############# FUNKTIONEN NACH STARTSEQUENZ

'					Verzögerte Umschaltung der Menüseiten
					(L.L.ibis_display) (L.L.ibis_display_req) = !
						{if}
							"" (S.$.zeile_R1) (S.$.zeile_R2) (S.$.zeile_R3) (S.$.zeile_R4) (S.$.zeile_oben) (S.$.zeile_delay)
							
							(L.L.ibis_menutimer) (L.S.Timegap) + (S.L.ibis_menutimer)
							(C.L.menu_delay) >
								{if}
									(L.L.ibis_display) (S.L.ibis_display_prev)
									(L.L.ibis_display_req) (S.L.ibis_display)
									
									(L.L.ibis_display_req) 2 =	
									(L.$.ibis_linie) $length 0 > &&
										{if}
											(L.$.ibis_linie) (S.$.input)
										{endif}
										
									(L.L.ibis_display_req) 3 =	
									(L.$.ibis_kurs) $length 0 > &&
										{if}
											(L.$.ibis_kurs) (S.$.input)
										{endif}	
										
									0 (S.L.ibis_menutimer)
								{endif}
						{endif}
										
'					Debug
					(L.L.int_routeindex) 0 < {if} 0 (S.L.ibis_stopcount) (S.L.ibis_stop) {endif}

					(L.L.ibis_display) 2 <
						{if}
							0 (S.L.ibis_klickN0) (S.L.ibis_klickN1) (S.L.ibis_klickN2) (S.L.ibis_klickN3) (S.L.ibis_klickN4) (S.L.ibis_klickN5) (S.L.ibis_klickN6)
							(S.L.ibis_klickN7) (S.L.ibis_klickN8) (S.L.ibis_klickN9) (S.L.ibis_klickNesc) (S.L.ibis_klickNenter) (S.L.ibis_klickR1) (S.L.ibis_klickR2) (S.L.ibis_klickR3) (S.L.ibis_klickR4) (S.L.ibis_klickU1) (S.L.ibis_klickU2) 
							(S.L.ibis_klickU3) (S.L.ibis_klickU4)  (S.L.ibis_klickU5) (S.L.ibis_klickNhoch)
							"" (S.$.ibis_innenanz)
						{else}
							
							(L.L.int_routeindex) -1 >
							(L.L.ibis_stopcount) 0 > &&
								{if}
									(L.L.ibis_stop) (L.L.ibis_stopcount) < {if} (L.L.int_routeindex) (L.L.ibis_stop) (M.V.GetRouteBusstopIdent) (M.V.GetBusstopIndex) 1 (M.V.GetBusstopString) (S.$.ibis_innenanz)	{else} "" (S.$.ibis_innenanz) {endif}
								{else}
									"" (S.$.ibis_innenanz)							
								{endif}
							
						{endif}
						
					(L.L.ibis_display) 5 = !
						{if}
							1 (S.L.ibis_zielcursor_upd) 
							-1 (S.L.ibis_zielcursor_last)
							0 (S.L.ibis_klickU3) (S.L.ibis_klickU4)  (S.L.ibis_klickU5)
						{endif}
						
'					Wenn Zündschlüssel ausgeschaltet wird:
					(L.L.elec_busbar_main_sw) !
						{if}							
							(L.L.int_routeindex) -1 >
								{if}
									7 (S.L.ibis_display_req)
								{else}
									8 (S.L.ibis_display_req)
								{endif}								
						{endif}

'					Wippschalter Fortschaltung
					(L.L.ibis_sw_fortschaltung)
					(L.L.ibis_stopcount) 0 > &&
					(L.L.ibis_stop_adv_lock) ! &&
						{if}
							1 (S.L.ibis_stop_adv_lock)
								
							(L.L.ibis_stop) (L.L.ibis_stopcount) 1 - < &&
								{if}
									(L.L.ibis_stop) 1 + (S.L.ibis_stop)
								{else}
									0 (S.L.ibis_stop)					
								{endif}
						{endif}				
						
						
' ################# MENÜ 2 ANMELDUNG LINIE			
					(L.L.ibis_display) 2 =
						{if}
						
							(L.L.ibis_klickN0)
								{if}
									(L.$.input) $length 4 <
										{if}
											(L.$.input) "0" $+ (S.$.input)
										{endif}
									0 (S.L.ibis_klickN0)
								{endif}
								
							(L.L.ibis_klickN1)
								{if}
									(L.$.input) $length 4 <
										{if}
											(L.$.input) "1" $+ (S.$.input)
										{endif}
									0 (S.L.ibis_klickN1)
								{endif}
								
							(L.L.ibis_klickN2)
								{if}
									(L.$.input) $length 4 <
										{if}
											(L.$.input) "2" $+ (S.$.input)
										{endif}
									0 (S.L.ibis_klickN2)
								{endif}
								
							(L.L.ibis_klickN3)
								{if}
									(L.$.input) $length 4 <
										{if}
											(L.$.input) "3" $+ (S.$.input)
										{endif}
									0 (S.L.ibis_klickN3)
								{endif}

							(L.L.ibis_klickN4)
								{if}
									(L.$.input) $length 4 <
										{if}
											(L.$.input) "4" $+ (S.$.input)
										{endif}
									0 (S.L.ibis_klickN4)
								{endif}

							(L.L.ibis_klickN5)
								{if}
									(L.$.input) $length 4 <
										{if}
											(L.$.input) "5" $+ (S.$.input)
										{endif}
									0 (S.L.ibis_klickN5)
								{endif}

							(L.L.ibis_klickN6)
								{if}
									(L.$.input) $length 4 <
										{if}
											(L.$.input) "6" $+ (S.$.input)
										{endif}
									0 (S.L.ibis_klickN6)
								{endif}

							(L.L.ibis_klickN7)
								{if}
									(L.$.input) $length 4 <
										{if}
											(L.$.input) "7" $+ (S.$.input)
										{endif}
									0 (S.L.ibis_klickN7)
								{endif}	
								
							(L.L.ibis_klickN8)
								{if}
									(L.$.input) $length 4 <
										{if}
											(L.$.input) "8" $+ (S.$.input)
										{endif}
									0 (S.L.ibis_klickN8)
								{endif}
								
							(L.L.ibis_klickN9)
								{if}
									(L.$.input) $length 4 <
										{if}
											(L.$.input) "9" $+ (S.$.input)
										{endif}
									0 (S.L.ibis_klickN9)
								{endif}
								
							(L.L.ibis_klickNesc)
								{if}
									(L.$.input) $length 0 >
										{if}
											(L.$.input) 1 $cutEnd (S.$.input)
										{endif}
									0 (S.L.ibis_klickNesc)
								{endif}
								
							(L.L.ibis_klickNenter)
								{if}
									(L.$.input) (S.$.ibis_linie)
									"" (S.$.input)									
									3 (S.L.ibis_display_req)									
									0 (S.L.ibis_klickNenter)
								{endif}	
							
							(L.L.ibis_klickR1)
							(L.L.ibis_klickR3) ||
							(L.L.ibis_klickR4) ||
							(L.L.ibis_klickU1) ||
							(L.L.ibis_klickNhoch) ||
								{if}
									0 (S.L.ibis_klickR1) (S.L.ibis_klickR3) (S.L.ibis_klickR4) (S.L.ibis_klickU1) (S.L.ibis_klickNhoch)
								{endif}								
							
							(L.L.ibis_klickU2)
								{if}
									0 (S.L.ibis_klickU2)
									6 (S.L.ibis_display_req)
								{endif}
								
							(L.L.ibis_klickR2)
								{if}
									(L.$.input) (S.$.ibis_linie)
									"" (S.$.input)									
									3 (S.L.ibis_display_req)
									0 (S.L.ibis_klickR2)
								{endif}	
								
							(L.$.input) "#" $+ (S.$.zeile_R1)
							(L.$.ibis_kurs) $length 0 >
								{if}
									(L.$.ibis_kurs) (S.$.zeile_R2)
								{else}
									"" (S.$.zeile_R2)
								{endif}
								
							"" (S.$.zeile_oben) (S.$.zeile_delay)
							
						{else}
						
' ################# MENÜ 3 ANMELDUNG KURS		
					(L.L.ibis_display) 3 =
						{if}
						
							(L.L.ibis_klickN0)
								{if}
									(L.$.input) $length 2 <
										{if}
											(L.$.input) "0" $+ (S.$.input)
										{endif}
									0 (S.L.ibis_klickN0)
								{endif}
								
							(L.L.ibis_klickN1)
								{if}
									(L.$.input) $length 2 <
										{if}
											(L.$.input) "1" $+ (S.$.input)
										{endif}
									0 (S.L.ibis_klickN1)
								{endif}
								
							(L.L.ibis_klickN2)
								{if}
									(L.$.input) $length 2 <
										{if}
											(L.$.input) "2" $+ (S.$.input)
										{endif}
									0 (S.L.ibis_klickN2)
								{endif}
								
							(L.L.ibis_klickN3)
								{if}
									(L.$.input) $length 2 <
										{if}
											(L.$.input) "3" $+ (S.$.input)
										{endif}
									0 (S.L.ibis_klickN3)
								{endif}

							(L.L.ibis_klickN4)
								{if}
									(L.$.input) $length 2 <
										{if}
											(L.$.input) "4" $+ (S.$.input)
										{endif}
									0 (S.L.ibis_klickN4)
								{endif}

							(L.L.ibis_klickN5)
								{if}
									(L.$.input) $length 2 <
										{if}
											(L.$.input) "5" $+ (S.$.input)
										{endif}
									0 (S.L.ibis_klickN5)
								{endif}

							(L.L.ibis_klickN6)
								{if}
									(L.$.input) $length 2 <
										{if}
											(L.$.input) "6" $+ (S.$.input)
										{endif}
									0 (S.L.ibis_klickN6)
								{endif}

							(L.L.ibis_klickN7)
								{if}
									(L.$.input) $length 2 <
										{if}
											(L.$.input) "7" $+ (S.$.input)
										{endif}
									0 (S.L.ibis_klickN7)
								{endif}	
								
							(L.L.ibis_klickN8)
								{if}
									(L.$.input) $length 2 <
										{if}
											(L.$.input) "8" $+ (S.$.input)
										{endif}
									0 (S.L.ibis_klickN8)
								{endif}
								
							(L.L.ibis_klickN9)
								{if}
									(L.$.input) $length 2 <
										{if}
											(L.$.input) "9" $+ (S.$.input)
										{endif}
									0 (S.L.ibis_klickN9)
								{endif}
								
							(L.L.ibis_klickNesc)
								{if}
									(L.$.input) $length 0 >
										{if}
											(L.$.input) 1 $cutEnd (S.$.input)
										{endif}
									0 (S.L.ibis_klickNesc)
								{endif}
								
							(L.L.ibis_klickNenter)
								{if}
									(L.$.input) (S.$.ibis_kurs)
									"" (S.$.input) (S.$.zeile_R1) (S.$.zeile_R2) (S.$.zeile_R3) (S.$.zeile_R4) (S.$.zeile_oben)
									
									(M.L.likrs_check)									
									(L.L.int_routeindex) -1 >
										{if}
											4 (S.L.ibis_display_req)
											
'											Uebernahme Linie/Ziel
											(L.L.int_routeindex) (M.V.GetRouteTerminusIndex) s0 -1 >
											l0 (L.L.IBIS_TerminusIndex) = ! &&
												{if}
													l0 (S.L.IBIS_TerminusIndex) (M.V.GetTerminusCode) (S.L.IBIS_TerminusCode) -1 (S.L.matrix_steckschild_Termindex) -1 (S.L.Matrix_TerminusIndex_Last) 
												{endif}
								
											(L.$.ibis_linie) (S.$.Matrix_Nr)
											
'											Anzahl Haltestellen speichern
											(L.L.int_routeindex) (M.V.GetBusstopCount) (S.L.ibis_stopcount)
											-1 (S.L.ibis_stop_last) (S.L.ibis_stop_ansag) 
											0 (S.L.ibis_stop)
											
										{else}
											(L.$.ibis_kurs) $length 0 >
											(L.$.ibis_linie) $length 0 > ||
												{if}
													9 (S.L.ibis_display_req)
												{else}
													"" (S.$.ibis_kurs) (S.$.ibis_linie)
												{endif}											
										{endif}
										
									0 (S.L.ibis_klickNenter)
								{endif}	
								
							(L.L.ibis_klickU2)
								{if}
									0 (S.L.ibis_klickU2)
									6 (S.L.ibis_display_req)
								{endif}	
								
							(L.L.ibis_klickR2)
							(L.L.ibis_klickR3) ||
							(L.L.ibis_klickR4) ||
							(L.L.ibis_klickU1) ||
							(L.L.ibis_klickNhoch) ||
								{if}
									0 (S.L.ibis_klickR2) (S.L.ibis_klickU1) (S.L.ibis_klickNhoch) (S.L.ibis_klickR3) (S.L.ibis_klickR4)
								{endif}
								
							(L.L.ibis_klickR1)
								{if}
									(L.$.input) (S.$.ibis_kurs)
									"" (S.$.input)									
									2 (S.L.ibis_display_req)
									0 (S.L.ibis_klickR1)
								{endif}		
							
							(L.$.ibis_linie) $length 0 >
								{if}
									(L.$.ibis_linie) (S.$.zeile_R1)
								{else}
									"" (S.$.zeile_R1)
								{endif}
								
							(L.$.input) "#" $+ (S.$.zeile_R2)
							
							"" (S.$.zeile_oben) (S.$.zeile_delay)
							
						{else}
						
' ################# MENÜ 4 RELATIVER FAHRPLAN	
					(L.L.ibis_display) 4 =
						{if}						
							
							(L.L.int_routeindex) s0
							0 < {if} 2 (S.L.ibis_display_req) {endif}
							
'							Aktuelle Linie/Ziel oben anzeigen						
							(L.$.Matrix_Nr) $length 1 <
								{if}
									"    "								
								{endif}							
							4 $SetLengthL
							"  " $+							
							(L.L.Matrix_TerminusAct) 5 (M.V.GetTerminusString) $+
							(S.$.zeile_oben)

							(L.L.ibis_stopcount) 0 <= (L.L.ibis_stop) (L.L.ibis_stop_last) = ! ||						
								{if}
									
'									Wenn Route aktiv, Haltestellenliste anzeigen								
									(L.L.ibis_stop) (L.L.ibis_stopcount) < {if} l0 (L.L.ibis_stop) (M.V.GetRouteBusstopIdent) (M.V.GetBusstopIndex) 1 (M.V.GetBusstopString) (S.$.zeile_R4) {else} "" (S.$.zeile_R4) {endif}
									(L.L.ibis_stop) 1 + (L.L.ibis_stopcount) < {if} l0 (L.L.ibis_stop) 1 + (M.V.GetRouteBusstopIdent) (M.V.GetBusstopIndex) 1 (M.V.GetBusstopString) (S.$.zeile_R3) {else} "" (S.$.zeile_R3) {endif}
									(L.L.ibis_stop) 2 + (L.L.ibis_stopcount) < {if} l0 (L.L.ibis_stop) 2 + (M.V.GetRouteBusstopIdent) (M.V.GetBusstopIndex) 1 (M.V.GetBusstopString) (S.$.zeile_R2) {else} "" (S.$.zeile_R2) {endif}
									(L.L.ibis_stop) 3 + (L.L.ibis_stopcount) < {if} l0 (L.L.ibis_stop) 3 + (M.V.GetRouteBusstopIdent) (M.V.GetBusstopIndex) 1 (M.V.GetBusstopString) (S.$.zeile_R1) {else} "" (S.$.zeile_R1) {endif}
									
									(L.L.ibis_stop) (S.L.ibis_stop_last)		

								{endif}
								
							(L.L.schedule_active)
								{if}
									(M.V.GetTTDelay) 0 >
										{if}
											(M.V.GetTTDelay) 10 >
												{if} 
													"+" (M.V.GetTTDelay) abs 60.0 / s0 l0 trunc "02" $IntToStrEnh $+ ":" $+ 
													(M.V.GetTTDelay) abs 60.0 / s0 l0 trunc (M.V.GetTTDelay) abs 60.0 / - /-/ 6 * trunc 10 * "02" $IntToStrEnh $+
												{else}												
													" " (M.V.GetTTDelay) 10 - abs 60.0 / s0 l0 trunc "02" $IntToStrEnh $+ ":" $+ 
													(M.V.GetTTDelay) 10 - abs 60.0 / s0 l0 trunc (M.V.GetTTDelay) 10 - abs 60.0 / - /-/ 6 * trunc 10 * "02" $IntToStrEnh $+
												{endif}
										{else}
					
											"-" (M.V.GetTTDelay) 10 - abs 60.0 / s0 l0 trunc "02" $IntToStrEnh $+ ":" $+ 
											(M.V.GetTTDelay) 10 - abs 60.0 / s0 l0 trunc (M.V.GetTTDelay) 10 - abs 60.0 / - /-/ 6 * trunc "02" 10 * $IntToStrEnh $+
											
										{endif}
										
										(S.$.zeile_delay)
										
								{else}
									"--:--" (S.$.zeile_delay)
								{endif}
							
							(L.L.ibis_klickNhoch)
								{if}									
									0 (S.L.ibis_klickNhoch) (S.L.ibis_stop_adv_lock)
									
									(L.L.ibis_stopcount) 0 >
									(L.L.ibis_stop_adv_lock) ! &&
										{if}
											(L.L.ibis_stop) (L.L.ibis_stopcount) 1 - < &&
												{if}
													(L.L.ibis_stop) 1 + (S.L.ibis_stop)
												{else}
													0 (S.L.ibis_stop)					
												{endif}
										{endif}									
								{endif}
								
							(L.L.ibis_klickNesc) (L.L.ibis_klickR4) ||
								{if}									
									0 (S.L.ibis_klickNesc) (S.L.ibis_klickR4) (S.L.ibis_stop_adv_lock)
									
									(L.L.ibis_stop) 0 >
										{if}		
											(L.L.ibis_stop) 1 - (S.L.ibis_stop)
										{endif}									
								{endif}	
							
							(L.L.ibis_klickU1)
								{if}
									2 (S.L.ibis_display_req)
									0 (S.L.ibis_klickU1)
								{endif}
								
							(L.L.ibis_klickU2)
								{if}
									0 (S.L.ibis_klickU2)
									6 (S.L.ibis_display_req)
								{endif}	
								
							(L.L.ibis_klickR1)
							(L.L.ibis_klickR2) ||
							(L.L.ibis_klickR3) ||
								{if}
									0 (S.L.ibis_klickR1) (S.L.ibis_klickR2) (S.L.ibis_klickR3)
								{endif}
								
							0 (S.L.ibis_klickN0) (S.L.ibis_klickN1) (S.L.ibis_klickN2) (S.L.ibis_klickN3) (S.L.ibis_klickN4) (S.L.ibis_klickN5) (S.L.ibis_klickN6)
							(S.L.ibis_klickN7) (S.L.ibis_klickN8) (S.L.ibis_klickN9) (S.L.ibis_klickNesc) (S.L.ibis_klickNenter)
													
						{else}
						
							"" (S.$.zeile_delay)
							
' ################# MENÜ 5 ZIEL/SONDERZIEL	
					(L.L.ibis_display) 5 =
						{if}				

							(L.L.ibis_zielcursor_upd)
								{if}
									(L.L.ibis_zielcursor) 0 (M.V.GetTerminusString) $length 0 > {if} (S.$.zeile_R4) {else} "" (S.$.zeile_R4) (L.L.ibis_zielcursor) (S.L.ibis_zielcursor_last) {endif}
									(L.L.ibis_zielcursor) 1 + 0 (M.V.GetTerminusString) $length 0 > {if} (S.$.zeile_R3) {else} "" (S.$.zeile_R3) (L.L.ibis_zielcursor) 1 + (S.L.ibis_zielcursor_last) {endif}
									(L.L.ibis_zielcursor) 2 + 0 (M.V.GetTerminusString) $length 0 > {if} (S.$.zeile_R2) {else} "" (S.$.zeile_R2) (L.L.ibis_zielcursor) 2 + (S.L.ibis_zielcursor_last) {endif}
									(L.L.ibis_zielcursor) 3 + 0 (M.V.GetTerminusString) $length 0 > {if} (S.$.zeile_R1) {else} "" (S.$.zeile_R1) (L.L.ibis_zielcursor) 3 + (S.L.ibis_zielcursor_last) {endif}
									0 (S.L.ibis_zielcursor_upd)
								{endif}
								
							(L.L.ibis_klickNhoch)
							(L.L.ibis_klickU4) ||
								{if}
									(L.L.ibis_zielcursor) (L.L.ibis_zielcursor_last) 4 - <
									(L.L.ibis_zielcursor_last) -1 = ||
										{if}
											(L.L.ibis_zielcursor) 4 + (S.L.ibis_zielcursor)
											1 (S.L.ibis_zielcursor_upd)
										{endif}									
									0 (S.L.ibis_klickNhoch)	(S.L.ibis_klickU4)
								{endif}
								
							(L.L.ibis_klickU5)	
								{if}
									(L.L.ibis_zielcursor) 4 >=
										{if}
											(L.L.ibis_zielcursor) 4 - (S.L.ibis_zielcursor)
											1 (S.L.ibis_zielcursor_upd)
										{endif}
										
									0 (S.L.ibis_klickU5)
								{endif}
								
							(L.L.ibis_klickU1)
								{if}
									(L.L.ibis_display_prev) (S.L.ibis_display_req)
									0 (S.L.ibis_klickU1)
								{endif}								

							(L.L.ibis_klickR4) 
								{if}
									(L.$.ibis_linie) (S.$.Matrix_Nr)
									(L.L.ibis_zielcursor) (S.L.IBIS_TerminusIndex) (M.V.GetTerminusCode) (S.L.IBIS_TerminusCode) -1 (S.L.matrix_steckschild_Termindex) -1 (S.L.Matrix_TerminusIndex_Last) 
									0 (S.L.ibis_klickR4)
									(L.L.ibis_display_prev) (S.L.ibis_display_req)
								{endif}
								
							(L.L.ibis_klickR3) 
								{if}
									(L.$.ibis_linie) (S.$.Matrix_Nr)
									(L.L.ibis_zielcursor) 1 + (S.L.IBIS_TerminusIndex) (M.V.GetTerminusCode) (S.L.IBIS_TerminusCode) -1 (S.L.matrix_steckschild_Termindex) -1 (S.L.Matrix_TerminusIndex_Last) 
									0 (S.L.ibis_klickR3)
									(L.L.ibis_display_prev) (S.L.ibis_display_req)
								{endif}	
								
							(L.L.ibis_klickR2) 
								{if}
									(L.$.ibis_linie) (S.$.Matrix_Nr)
									(L.L.ibis_zielcursor) 2 + (S.L.IBIS_TerminusIndex) (M.V.GetTerminusCode) (S.L.IBIS_TerminusCode) -1 (S.L.matrix_steckschild_Termindex) -1 (S.L.Matrix_TerminusIndex_Last) 
									0 (S.L.ibis_klickR2)
									(L.L.ibis_display_prev) (S.L.ibis_display_req)
								{endif}	
							
							(L.L.ibis_klickR1) 
								{if}
									(L.$.ibis_linie) (S.$.Matrix_Nr)
									(L.L.ibis_zielcursor) 3 + (S.L.IBIS_TerminusIndex) (M.V.GetTerminusCode) (S.L.IBIS_TerminusCode) -1 (S.L.matrix_steckschild_Termindex) -1 (S.L.Matrix_TerminusIndex_Last) 
									0 (S.L.ibis_klickR1)
									(L.L.ibis_display_prev) (S.L.ibis_display_req)
								{endif}	
							
							0 (S.L.ibis_klickN0) (S.L.ibis_klickN1) (S.L.ibis_klickN2) (S.L.ibis_klickN3) (S.L.ibis_klickN4) (S.L.ibis_klickN5) (S.L.ibis_klickN6)
							(S.L.ibis_klickN7) (S.L.ibis_klickN8) (S.L.ibis_klickN9) (S.L.ibis_klickNesc) (S.L.ibis_klickNenter) (S.L.ibis_klickU2) (S.L.ibis_klickU3)
							
						{else}
						
' ################# MENÜ 6 OPTIONSMENÜ	
					(L.L.ibis_display) 6 =
						{if}	
						
							(L.L.ibis_klickU1)
								{if}
									4 (S.L.ibis_display_req)
									-1 (S.L.ibis_stop_last)
									0 (S.L.ibis_klickU1)
								{endif}
								
							(L.L.ibis_klickR3)
								{if}
									2 (S.L.ibis_display_req)
									0 (S.L.ibis_klickR3)
								{endif}
								
							(L.L.ibis_klickU2)
							(L.L.ibis_klickR1)
								{if}
									0 (S.L.ibis_klickU2)
									0 (S.L.ibis_klickR1)
								{endif}
								
							(L.L.ibis_klickR2)
								{if}
									0 (S.L.ibis_klickR2)
								{endif}
								
							(L.L.ibis_klickR4)
								{if}
									5 (S.L.ibis_display_req)
									0 (S.L.ibis_klickR4)
								{endif}		
								
							0 (S.L.ibis_klickN0) (S.L.ibis_klickN1) (S.L.ibis_klickN2) (S.L.ibis_klickN3) (S.L.ibis_klickN4) (S.L.ibis_klickN5) (S.L.ibis_klickN6)
							(S.L.ibis_klickN7) (S.L.ibis_klickN8) (S.L.ibis_klickN9) (S.L.ibis_klickNesc) (S.L.ibis_klickNenter)  (S.L.ibis_klickNhoch)
							
						{else}
						
						
' ################# MENÜ 7 SELBSTHALTUNG
					(L.L.ibis_display) 7 =
						{if}		
							(L.L.elec_busbar_main)
								{if}
									(L.L.ibis_display_prev) (S.L.ibis_display_req)
								{endif}
								
							-1 (S.L.ibis_stop_last)	
						
							"" (S.$.zeile_R1) (S.$.zeile_R2) (S.$.zeile_R3) (S.$.zeile_R4) (S.$.zeile_oben)
							
							0 (S.L.ibis_klickN0) (S.L.ibis_klickN1) (S.L.ibis_klickN2) (S.L.ibis_klickN3) (S.L.ibis_klickN4) (S.L.ibis_klickN5) (S.L.ibis_klickN6)
							(S.L.ibis_klickN7) (S.L.ibis_klickN8) (S.L.ibis_klickN9) (S.L.ibis_klickNesc) (S.L.ibis_klickNenter)  (S.L.ibis_klickNhoch) (S.L.ibis_klickU1) (S.L.ibis_klickU2) (S.L.ibis_klickR1) (S.L.ibis_klickR2) (S.L.ibis_klickR3) (S.L.ibis_klickR4)
						{else}
						
						
' ################# MENÜ 8 ABMELDEN
					(L.L.ibis_display) 8 =
						{if}
							(L.L.ibis_logofftimer) (L.S.Timegap) + (S.L.ibis_logofftimer)
							8 >
								{if}
									(M.L.ibis_aus)
								{endif}						
						
							"" (S.$.zeile_R1) (S.$.zeile_R2) (S.$.zeile_R3) (S.$.zeile_R4) (S.$.zeile_oben) (S.$.zeile_delay)
							
							0 (S.L.ibis_klickN0) (S.L.ibis_klickN1) (S.L.ibis_klickN2) (S.L.ibis_klickN3) (S.L.ibis_klickN4) (S.L.ibis_klickN5) (S.L.ibis_klickN6)
							(S.L.ibis_klickN7) (S.L.ibis_klickN8) (S.L.ibis_klickN9) (S.L.ibis_klickNesc) (S.L.ibis_klickNenter)  (S.L.ibis_klickNhoch) (S.L.ibis_klickU1) (S.L.ibis_klickU2) (S.L.ibis_klickR1) (S.L.ibis_klickR2) (S.L.ibis_klickR3) (S.L.ibis_klickR4)
						{else}
						
						
' ################# MENÜ 9 FEHLER LIKRS		
					(L.L.ibis_display) 9 =
						{if}						
						
							(L.L.ibis_fehlertimer) (L.S.Timegap) + (S.L.ibis_fehlertimer)
							(C.L.fehler_dur) >
								{if}
									0 (S.L.ibis_fehlertimer)
									(L.L.ibis_display_prev) (S.L.ibis_display_req)
								{endif}
							
							"" (S.$.zeile_R1) (S.$.zeile_R2) (S.$.zeile_R3) (S.$.zeile_R4) (S.$.zeile_oben)
								
							(L.L.ibis_klickR1)
							(L.L.ibis_klickR2) ||
							(L.L.ibis_klickU1) ||
							(L.L.ibis_klickU2) ||
							(L.L.ibis_klickNhoch) ||
								{if}
									0 (S.L.ibis_klickR1) (S.L.ibis_klickR2) (S.L.ibis_klickU1) (S.L.ibis_klickU2) (S.L.ibis_klickNhoch)
								{endif}
								
							0 (S.L.ibis_klickN0) (S.L.ibis_klickN1) (S.L.ibis_klickN2) (S.L.ibis_klickN3) (S.L.ibis_klickN4) (S.L.ibis_klickN5) (S.L.ibis_klickN6)
							(S.L.ibis_klickN7) (S.L.ibis_klickN8) (S.L.ibis_klickN9) (S.L.ibis_klickNesc) (S.L.ibis_klickNenter)  (S.L.ibis_klickNhoch)	
							
						{else}	

						
						{endif}
						{endif}
						{endif}
						{endif}
						{endif}
						{endif}
						{endif}
						{endif}
						
'						#################### Autom. Fortschaltung
						(L.L.int_routeindex) -1 >
						(L.L.int_routeindex) (M.V.GetRouteTerminusIndex) (M.V.GetTTTerminusIndex) = &&
						(L.L.ibis_stop) (M.V.GetTTBusstopIndex) < &&
						(L.L.schedule_active) &&
							{if}
								0 (M.V.GetTTBusstopName) 1 (M.V.GetTTBusstopName) $=
									{if}
										(M.V.GetTTBusstopIndex) 1 - 0 max (S.L.ibis_stop)
									{else}
										(M.V.GetTTBusstopIndex) (S.L.ibis_stop)
									{endif}								
							{endif}
			
'						#################### Ansage aufrufen
						(L.L.ibis_stop_ansag) (L.L.ibis_stop) = !
						(L.L.int_routeindex) -1 > &&
							{if}
								(L.L.ibis_stop) (S.L.ibis_stop_ansag)
								(M.L.ibis_ansage)				
							{endif}
						
						(L.L.ibis_stopcount) -1 =
						(L.L.int_routeindex) 0 < ||
							{if}
								-1 (S.L.ibis_stop_ansag)
							{endif}
						
'					Ende Fkt. nach Startsequenz					
					{endif}

'			Ende ibis_an		
				
			{endif}	
	
'	Ende Nicht-AI
	{endif}	

{end}

{macro:likrs_check}
	
	(L.$.ibis_linie) (L.$.ibis_kurs) $+ $StrToFloat
	(M.V.GetRouteIndex)
	(S.L.int_routeindex)

{end}

{macro:ibis_aus}

	0 (S.L.ibis_an)
	0 (S.L.ibis_starttimer) (S.L.ibis_menutimer) (S.L.ibis_fehlertimer) (S.L.ibis_logofftimer)
	
	-1 (S.L.ibis_display)
	
	"" (S.$.input) (S.$.zeile_delay) (S.$.zeile_R1) (S.$.zeile_R2) (S.$.zeile_R3) (S.$.zeile_R4) (S.$.zeile_oben)
	
	0 (S.L.ibis_klickN0) (S.L.ibis_klickN1) (S.L.ibis_klickN2) (S.L.ibis_klickN3) (S.L.ibis_klickN4) (S.L.ibis_klickN5) (S.L.ibis_klickN6)
	(S.L.ibis_klickN7) (S.L.ibis_klickN8) (S.L.ibis_klickN9) (S.L.ibis_klickNesc) (S.L.ibis_klickNenter)  (S.L.ibis_klickNhoch) (S.L.ibis_klickU1) (S.L.ibis_klickU2) (S.L.ibis_klickR1) (S.L.ibis_klickR2) (S.L.ibis_klickR3) (S.L.ibis_klickR4)
	
{end}

{macro:ibis_ansage}
    (L.L.ibis_stop_ansag) 0 >
        {if}
            "..\..\Announcements\" 
            0 (M.V.GetDepotStringGlobal) $+                        
            "\" $+ 
            (L.L.int_routeindex) (L.L.ibis_stop_ansag) (M.V.GetRouteBusstopIdent) $+
            (L.L.ibis_stopcount) (L.L.ibis_stop_ansag) 1 + =
            (L.L.ibis_stopcount) 3 > &&
                {if}
                    "_#terminus" $+
                {endif}
            
            ".wav" $+ 
            $msg (T.F.ev_IBIS_Ansagen)
        {endif}
{end}

{end}