{init}
	(M.L.elec_init)
	(M.L.antr_init)
	(M.L.engi_init)
	(M.L.brak_init)
	(M.L.tuer_init)
	(M.L.misc_init)
	(M.L.dash_init)
	(M.L.IAnz_init)
	(M.L.visu_init)
	(M.L.heat_init)
	(M.L.IVU_Ticketbox_init)
	(M.L.Matrix_init)
	1 (S.L.Refresh_Strings)
{end}


{frame}

	(L.$.ident) $length s0
	(L.$.ident) 1 $cutBegin l0 2 - $cutEnd "-" $=
	{if}
		(L.$.ident) l0 1 - $cutEnd (S.$.ident_int_1)
		(L.$.ident) 2 $cutBegin (S.$.ident_int_2)
		(L.$.ident) "@" $+ (L.$.ident_int_1) $+ "_" $+ (L.$.ident_int_2) $+ (S.$.ident_int)
	{else}
		(L.$.ident) 2 $cutBegin l0 3 - $cutEnd "-" $=
		{if}
			(L.$.ident) l0 2 - $cutEnd (S.$.ident_int_1)
			(L.$.ident) 3 $cutBegin (S.$.ident_int_2)
			(L.$.ident) "@" $+ (L.$.ident_int_1) $+ "_" $+ (L.$.ident_int_2) $+ (S.$.ident_int)
		{else}	
			(L.$.ident) 3 $cutBegin l0 4 - $cutEnd "-" $=
			{if}
				(L.$.ident) l0 3 - $cutEnd (S.$.ident_int_1)
				(L.$.ident) 4 $cutBegin (S.$.ident_int_2)
				(L.$.ident) "@" $+ (L.$.ident_int_1) $+ "_" $+ (L.$.ident_int_2) $+ (S.$.ident_int)
			{else}	
				(L.$.ident) (S.$.ident_int_1) (S.$.ident_int_2)				
				(L.$.ident_int_1) "@" $+ (L.$.ident_int_2) $+ (S.$.ident_int)
			{endif}
		{endif}
	{endif}

'Vehicletype:
' 0 = MAN SG
' 1 = MAN SL
' 2 = MAN SÜ
' 3 = MAN SM
'Fronttype:
' 0 = Standard
' 1 = StÜLB
	1 (S.L.main_Vehicletype)
	0 (S.L.main_Fronttype)
	(L.L.AI) !
	{if}
		(M.L.elec_frame)
		(M.L.antr_frame)
		(M.L.engi_frame)
		(M.L.brak_frame)
		(M.L.Gele_frame)
		(M.L.tuer_frame)
		(M.L.misc_frame)
		(M.L.dash_frame)
		(M.L.IAnz_frame)
		(M.L.cash_frame)
		(M.L.visu_frame)
		(M.L.heat_frame)
		(M.L.IVU_Ticketbox_frame)
		(M.L.Matrix_frame)
		1 (S.L.Refresh_Strings)
	{else}
		(M.L.elec_frame)
		(M.L.antr_frame)
		(M.L.engi_frame)
		(M.L.brak_frame)
		(M.L.tuer_frame)
		(M.L.visu_frame)
		(M.L.Matrix_frame)
		1 (S.L.Refresh_Strings)	
	{endif}
	(L.L.AI)
	{if}
		955000 (S.L.bremse_p_Tank01) (S.L.bremse_p_Tank02) (S.L.bremse_p_Tank03) (S.L.bremse_p_Tank04) (S.L.bremse_p_leitung01) (S.L.bremse_p_leitung02)
		0.8 (S.L.Axle_Springfactor_0_R) (S.L.Axle_Springfactor_1_R) (S.L.Axle_Springfactor_2_R) (S.L.Axle_Springfactor_0_L) (S.L.Axle_Springfactor_1_L) (S.L.Axle_Springfactor_2_L)
	
		(L.L.Brake) 40000 * (S.L.Axle_Brakeforce_0_R) (S.L.Axle_Brakeforce_0_L) (S.L.Axle_Brakeforce_1_R) (S.L.Axle_Brakeforce_1_L) (S.L.Axle_Brakeforce_2_R) (S.L.Axle_Brakeforce_2_L)
		(L.L.Brake) 950000 * (S.L.bremse_p_Brzyl_HA)
		
		1 (S.L.elec_busbar_main)
		(L.L.AI_Scheduled_AtStation) -1 =
		{if}
			(L.L.engine_on) !
			{if}
				1 (S.L.engine_starter) (S.L.engine_injection_on)
				(L.L.main_ai_enginestartstop_sound_lock) !
				{if}
					(T.L.ev_engine_starter)
					1 (S.L.main_ai_enginestartstop_sound_lock)
				{endif}
			{endif}
			(L.L.engine_on)
			{if}
				0 (S.L.engine_starter)
			{endif}
			(L.L.engine_on)
			(L.L.antrieb_getr_gangvorwahl) 5 = !
			{if}
				(L.S.getTime) (S.L.antrieb_getr_gangwahlzeitpunkt)
				5 (S.L.antrieb_getr_gangvorwahl)
				0 (S.L.bremse_feststell) (S.L.bremse_feststell_sw)
				3 (S.L.main_ai_timer)
			{endif}
			(L.L.antrieb_getr_aktugang) 0 >=
			{if}
				0 (S.L.doortarget_01)
				0 (S.L.doortarget_23)
				0 (S.L.doortarget_45)
				(L.L.main_ai_timer) (L.S.Timegap) - (S.L.main_ai_timer) 0 <=
				(L.L.door0) 0 <= &&
				(L.L.door1) 0 <= &&
				(L.L.door2) 0 <= &&
				(L.L.door3) 0 <= &&
				(L.L.door4) 0 <= &&
				(L.L.door5) 0 <= &&
				{if}
					0 (S.L.AI_Scheduled_AtStation)
					0 (S.L.door_freigabe)
					0 (S.L.bremse_halte)
					0 (S.L.main_ai_door01_timer) (S.L.main_ai_door23_timer) (S.L.main_ai_door45_timer)
				{endif}
			{endif}
			
		{endif}
		(L.L.AI_Scheduled_AtStation) 1 =		
		{if}
			1 (S.L.bremse_halte)
			1 (S.L.door_freigabe)

			(L.L.PAX_Exit0_Req)
			(L.L.PAX_Entry0_Req) ||
			(L.L.PAX_Entry1_Req) ||
			{if}
				(L.L.Velocity_Ground) 0.1 <
				{if}
					1 (S.L.doortarget_01)
					3 (S.L.main_ai_door01_timer)
				{endif}
			{else}
				(L.L.main_ai_door01_timer) (L.S.Timegap) - (S.L.main_ai_door01_timer) 0 <=
				{if}
					0 (S.L.doortarget_01)
				{endif}
			{endif}
			(L.L.PAX_Exit1_Req) 
			(L.L.PAX_Exit2_Req) ||
			(L.L.PAX_Entry2_Req) ||
			(L.L.PAX_Entry3_Req) ||				
			{if}
				(L.L.Velocity_Ground) 0.1 <
				{if}
					1 (S.L.doortarget_23)
					3.5 (S.L.main_ai_door23_timer)
				{endif}
			{else}
				(L.L.main_ai_door23_timer) (L.S.Timegap) - (S.L.main_ai_door23_timer) 0 <=
				{if}
					0 (S.L.doortarget_23)
				{endif}
			{endif}
			(L.L.PAX_Exit3_Req) 
			(L.L.PAX_Exit4_Req) ||
			(L.L.PAX_Entry4_Req) ||
			(L.L.PAX_Entry5_Req) ||				
			{if}
				1 (S.L.doortarget_45)
				3 (S.L.main_ai_door45_timer)
			{else}
				(L.L.main_ai_door45_timer) (L.S.Timegap) - (S.L.main_ai_door45_timer) 0 <=
				{if}
					0 (S.L.doortarget_45)
				{endif}
			{endif}	
			
		{endif}


		(L.L.doortarget_01) 
		{if}
			(L.L.main_ai_door01_sound_lock) !
			{if}
				(T.L.ev_door01_open)
				1 (S.L.main_ai_door01_sound_lock)
			{endif}
		{else}
			(L.L.main_ai_door01_sound_lock)
			{if}
				(T.L.ev_door01_close)
				0 (S.L.main_ai_door01_sound_lock)
			{endif}
		{endif}
		
		(L.L.doortarget_23) 
		{if}
			(L.L.main_ai_door23_sound_lock) !
			{if}
				(T.L.ev_door23_open)
				1 (S.L.main_ai_door23_sound_lock)
			{endif}
		{else}
			(L.L.main_ai_door23_sound_lock)
			{if}
				(T.L.ev_door23_close)
				0 (S.L.main_ai_door23_sound_lock)
			{endif}
		{endif}
						
		(L.L.AI_Engine) -1 =
			{if}
				(L.L.engine_on)
				{if}
					0 (S.L.engine_injection_on)
					1 (S.L.antrieb_getr_gangvorwahl) 
					1 (S.L.bremse_feststell) (S.L.bremse_feststell_sw)
					3 (S.L.main_ai_timer)
					(L.L.main_ai_enginestartstop_sound_lock)
					{if}
						(T.L.ev_engineshutdown)
						0 (S.L.main_ai_enginestartstop_sound_lock)
					{endif}
				{endif}
			{endif}
	{endif}
	
'Gleitkommafehler-Workaround nach Laden der Situation:
(L.L.IBIS_Linie) 0.3 + trunc (S.L.IBIS_Linie)
(L.L.IBIS_LinieKurs) 0.3 + trunc (S.L.IBIS_LinieKurs)
(L.L.IBIS_Mode) 0.3 + trunc (S.L.IBIS_Mode)
(L.L.IBIS_Mode) 0.3 + trunc (S.L.IBIS_Mode)

(L.L.AK_100_Mode) 0 >=
{if}
	(L.L.AK_100_Mode) 0.1 + trunc (S.L.AK_100_Mode)
{endif}

(L.L.AK_100_Mode_Prev) 0.1 + trunc (S.L.AK_100_Mode_Prev)

(L.L.AK_100_Cursor_UpDown) 0.1 + trunc (S.L.AK_100_Mode_Prev)
{end}