{macro:Cockpit_init}
	(S.L.cockpit_lights_init)
	0 (S.L.cockpit_hupe_volume)
	0 (S.L.cp_debug_vis)
	905 (S.L.cp_elec_utilities_timer)
	1 (S.L.doors_bremse)
	1 (S.L.bremse_stand_delay_rep)
	1 (S.L.bremse_stand_delay)
	(L.L.kmcounter_km) (S.L.cp_trip_km_1_reset_state)
	(L.L.engine_tank_content) (S.L.cp_trip_fuel_1_reset_state)
	0 (S.L.cp_trip_time_1_since_reset)
{end}

{macro:Cockpit_frame}
	(M.L.hupe_frame)
	(M.L.Cockpit_Display)
	(M.L.Cockpit_Lights)
	(M.L.Cockpit_Buttons_Lights)
	(M.L.Spheros_frame)
	(M.L.CP_Lights_frame)


	(L.L.kmcounter_km) (L.L.cp_trip_km_1_reset_state) - (S.L.cp_trip_km_1)
	(L.L.engine_tank_content) (L.L.cp_trip_fuel_1_reset_state) - (S.L.cp_trip_1_fuel_used)
	(L.L.cp_trip_1_fuel_used) abs (S.L.cp_trip_1_fuel_used)

	(L.L.cp_trip_1_fuel_used) 0 >
	(L.L.cp_trip_km_1) 0 > &&
	{if}
		(L.L.cp_trip_1_fuel_used) 100 * s0
		l0 (L.L.cp_trip_km_1) / (S.L.cp_trip_1_fuel_used_100)
	{else}
		0 (S.L.cp_trip_1_fuel_used_100)
	{endif}

	(L.L.cp_trip_time_1_since_reset) (L.S.Timegap) + (S.L.cp_trip_time_1_since_reset)

	(L.L.cp_trip_time_1_since_reset) 3600 / (S.L.cp_trip_time_1_since_reset_hr)

	(L.L.cp_trip_km_1) (L.L.cp_trip_time_1_since_reset_hr) / (S.L.cp_trip_1_avg_speed)


	(M.L.blinkerhebel_frame)
	(L.L.cp_wischer_schnell_sw) (S.L.wiper_schnell_sw)
	(L.L.cp_wischer_einaus_sw) (S.L.wiper_einaus_sw)
	(L.L.cp_wischer_intervall_sw) (S.L.wiper_intervall_sw)
	(L.L.cp_wischer_wascher_sw) (S.L.wiper_wascher_sw)


	(L.L.Cabinair_Temp) s0 trunc " 3" $IntToStrEnh "." $+ 
	l0 abs l0 abs trunc - 10 * trunc " 1" $IntToStrEnh $+ "C" $+
	(S.$.board_temp)



	(L.L.elec_busbar_main) 1 =
	(L.L.cp_defrost_mirrors_sw) 1 = &&
	{if}
		1 (S.L.cp_defrost_mirrors_sw_light)
	{else}
		0 (S.L.cp_defrost_mirrors_sw_light)
	{endif}

	(L.L.elec_busbar_main) 1 =
	(L.L.cp_defrost_door_sw) 1 = &&
	{if}
		1 (S.L.cp_defrost_door_sw_light)
	{else}
		0 (S.L.cp_defrost_door_sw_light)
	{endif}


{end}

{macro:Cockpit_Display}
	(L.L.elec_busbar_main) 1 =
	{if}
		(L.L.cockpit_system_init) (L.S.Timegap) + (S.L.cockpit_system_init)
		(L.L.cockpit_system_init) 3 <
		{if}
			1 (S.L.cockpit_lights_init) (S.L.board_initialization)
		{else}
			0 (S.L.cockpit_lights_init) (S.L.board_initialization)

			(L.L.board_initialization) 0 =
			(L.L.board_current) 0 = &&
			{if}
				1 (S.L.board_current)
			{endif}
		{endif}
	{else}
		0 (S.L.cockpit_system_init)
		0 (S.L.cockpit_lights_init) (S.L.board_initialization)
	{endif}

	(L.L.engine_adblue_content) abs (F.L.adblue_percent) (S.L.cockpit_adblue_level)

	(L.L.Velocity) abs (F.L.cockpit_tachy) (S.L.cockpit_tachymeter)

	(L.L.cockpit_rpm_ready) 1 =
	{if}
		(L.L.engine_n) (F.L.cockpit_rpm) s0

		(L.L.elec_busbar_main) !
		{if}
		0 s0
		{endif}

		(L.L.cockpit_rpm) s1
		5 s2
		5 s3
		(M.L.traegheit) 
		l1 (S.L.cockpit_rpm)
	{else}
		0 (S.L.cockpit_rpm)
	{endif}

	(L.L.elec_busbar_main)
	{if}
		(L.L.cockpit_lights_init) 0 =
		{if}
			(L.L.engine_temperature) (F.L.cockpit_engine_temperature) s0

			(L.L.elec_busbar_main) !
			{if}
			0 s0
			{endif}

			(L.L.cockpit_engine_temperature) s1
			5 s2
			5 s3
			(M.L.traegheit)	
			l1 (S.L.cockpit_engine_temperature)

			(L.L.cockpit_tank_timer) (L.S.Timegap) + (S.L.cockpit_tank_timer) 0.3 >
			{if}
				(L.L.engine_tank_content) (F.L.cockpit_tank) s0

				(L.L.elec_busbar_main) !
				{if}
				0 s0
				{endif}

				(L.L.cockpit_tank) s1
				5 s2
				5 s3
				(M.L.traegheit) 
				l1 (S.L.cockpit_tank)
			{endif}
		{else}
			0 (S.L.cockpit_engine_temperature) (S.L.cockpit_tank)
		{endif}
	{else}
		-3 (S.L.cockpit_engine_temperature) (S.L.cockpit_tank)
		0 (S.L.cockpit_tank_timer) (S.L.cockpit_light_fuel) (S.L.cockpit_light_temp)
	{endif}
{end}

{macro:Cockpit_Lights}

(L.L.lights_start_done) 1 =
{if}
	(L.L.lights_blinker_l) 1 = (L.L.elec_busbar_main) && (L.L.cockpit_lights_init) 1 = || (L.L.lights_warnblinkgeber) 1 = ||
	(S.L.cockpit_light_blink_l)

	(L.L.cockpit_asr_active) 2 = (L.L.elec_busbar_main) && (L.L.cockpit_lights_init) 1 = || (L.L.cp_asr_toggle_active) 1 = ||
	(S.L.cockpit_light_asr)

	(L.L.cp_driver_belt_sw) 0 = (L.L.elec_busbar_main) && (L.L.cockpit_lights_init) 1 = ||
	(S.L.cockpit_light_belt)

	(L.L.LimiterType) 1 = (L.L.elec_busbar_main) && (L.L.cockpit_lights_init) 1 = ||
	(S.L.cockpit_light_limiter)

	(L.L.CruiseActive) 2 = (L.L.elec_busbar_main) && (L.L.cockpit_lights_init) 1 = ||
	(S.L.cockpit_light_cruise)

	(L.L.lights_stand) 1 = (L.L.elec_busbar_main) && (L.L.cockpit_lights_init) 1 = ||
	(S.L.cockpit_light_park_lights)

	(L.L.lights_front_fogs) 1 = (L.L.elec_busbar_main) && (L.L.cockpit_lights_init) 1 = ||
	(S.L.cockpit_light_fog_f_lights)

	(L.L.lights_rear_fogs) 1 = (L.L.elec_busbar_main) && (L.L.cockpit_lights_init) 1 = ||
	(S.L.cockpit_light_fog_r_lights)

	(L.L.lights_fern) 1 = (L.L.elec_busbar_main) && (L.L.cockpit_lights_init) 1 = ||
	(S.L.cockpit_light_beam_lights)

	(L.L.lights_warnblinkgeber) 1 = (L.L.elec_busbar_main) && (L.L.cockpit_lights_init) 1 = ||
	(S.L.cockpit_light_warn_lights)

	(L.L.cockpit_failure) 1 = (L.L.elec_busbar_main) && (L.L.cockpit_lights_init) 1 = ||
	(S.L.cockpit_light_dashboard_fail)
	0 (S.L.cp_debug_vis)

    (L.L.elec_busbar_main)
    (L.L.RetarderCurrent) 2 > &&
    (L.L.RetarderSystemsActive) 1 = &&
	(L.L.cockpit_lights_init) 1 = ||
    {if}
        1 (S.L.cockpit_light_retarder)
		(L.L.cockpit_lights_init) 0 =
		{if}
        	1 (S.L.RetarderWorking)
		{endif}
    {else}
        0 (S.L.cockpit_light_retarder)
        0 (S.L.RetarderWorking)
    {endif} 

    (L.L.elec_busbar_main)
    (L.L.RetarderCurrent) 0 > &&
    (L.L.RetarderSystemsActive) 1 = &&
	(L.L.cockpit_lights_init) 1 = ||
    {if}
		(L.L.cockpit_lights_init) 0 =
		{if}
			(L.L.engine_n) 650 >
			{if}
				(L.L.EngineBrakeDelayTimer) (L.S.Timegap) + (S.L.EngineBrakeDelayTimer) (C.L.MotorBrakeDelay) >
				(L.L.clutch) 0.15 < &&
				{if}
					1 (S.L.cockpit_light_enginebrake)
					0 (S.L.EngineBrakeDelayTimer)
				{endif}
				0 (S.L.EngineBrakeBlinkTimer)
			{else}
				(L.L.EngineBrakeBlinkTimer) (L.S.Timegap) + (S.L.EngineBrakeBlinkTimer) 1 >
				{if}
					0 (S.L.EngineBrakeBlinkTimer)

					(L.L.cockpit_light_enginebrake) 0 =
					(L.L.clutch) 0.15 < &&
					{if}
						1 (S.L.cockpit_light_enginebrake)
					{else}
						0 (S.L.cockpit_light_enginebrake)
					{endif}
				{endif}
			{endif}
		{else}
			1 (S.L.cockpit_light_enginebrake)
			0 (S.L.EngineBrakeBlinkTimer)
		{endif}
    {else}
        0 (S.L.cockpit_light_enginebrake)
		0 (S.L.EngineBrakeBlinkTimer)
    {endif}



    (L.L.elec_busbar_main)
    {if}
		(L.L.cockpit_lights_init) 0 =
		{if}
			(L.L.engine_n) 100 <
			{if}
				(L.L.cockpit_light_obd_active) 0 =
				{if}
					(L.L.cockpit_light_obd_timer) (L.S.Timegap) + (S.L.cockpit_light_obd_timer) 5 >
					{if}
						1 (S.L.cockpit_light_obd_active)
						0 (S.L.cockpit_light_obd_timer)
					{endif}
				{else}
					(L.L.cockpit_light_obd_timer) (L.S.Timegap) + (S.L.cockpit_light_obd_timer) 1 >
					{if}
						0 (S.L.cockpit_light_obd_active)
						0 (S.L.cockpit_light_obd_timer)
					{endif}
				{endif}
			{else}
				0 (S.L.cockpit_light_obd_active)
			{endif}
		{else}
			1 (S.L.cockpit_light_obd_active)
			0 (S.L.cockpit_light_obd_timer)
		{endif}
    {else}
        0 (S.L.cockpit_light_obd_active)
		0 (S.L.cockpit_light_obd_timer)
    {endif}



	(L.L.bremse_ABS_eingriff) 1 = (L.L.elec_busbar_main) && (L.L.cockpit_lights_init) 1 = ||
	(S.L.cockpit_light_abs)

	(L.L.cockpit_light_obd_active) 1 = (L.L.elec_busbar_main) && (L.L.cockpit_lights_init) 1 = ||
	(S.L.cockpit_light_obd)

	(L.L.lights_blinker_r) 1 = (L.L.elec_busbar_main) && (L.L.cockpit_lights_init) 1 = || (L.L.lights_warnblinkgeber) 1 = ||
	(S.L.cockpit_light_blink_r)

	(L.L.elec_busbar_main)
	{if}
		(L.L.cockpit_alarm_pressure_interval) (L.S.Timegap) + (S.L.cockpit_alarm_pressure_interval) 2 >
		{if}
			0 (S.L.cockpit_alarm_pressure_interval)

			(L.L.bremse_p_Tank01) 600000 <
			(L.L.bremse_p_Tank02) 600000 < &&
			{if}
				1 (S.L.cockpit_alarm_pressure)
			{else}
				0 (S.L.cockpit_alarm_pressure)
			{endif}
		{endif}
	{else}
		0 (S.L.cockpit_alarm_pressure)
		5 (S.L.cockpit_alarm_pressure_interval)
	{endif}


	(L.L.elec_busbar_main)
	{if}
		(L.L.cp_susp_mode) 1 =
		(L.L.Velocity) 30 > &&
		{if}
			(C.L.bremse_level_setpoint) (S.L.bremse_level_setpoint)
		{else}
		(L.L.cp_susp_mode) 2 =
		(L.L.Velocity) 5 > &&
		{if}
			(C.L.bremse_level_setpoint) (S.L.bremse_level_setpoint)
		{endif}
		{endif}
	{endif}
		

	(L.L.cockpit_alarm_pressure) 1 = (L.L.elec_busbar_main) && (L.L.cockpit_lights_init) 1 = ||
	(S.L.cockpit_light_air_pressure)

	(L.L.doors_bremse) 1 = (L.L.elec_busbar_main) && (L.L.cockpit_lights_init) 1 = ||
	(S.L.cockpit_light_door_brake)

	(L.L.bremse_feststell) 1 = (L.L.elec_busbar_main) && (L.L.cockpit_lights_init) 1 = ||
	(S.L.cockpit_light_parking_brake)

	(L.L.cp_brake_valve_bremse) 1 = (L.L.elec_busbar_main) && (L.L.cockpit_lights_init) 1 = ||
	(S.L.cockpit_light_brake_valve)
'
'
	(L.L.cockpit_tachy_active_b) 0 = (L.L.elec_busbar_main) && (L.L.cockpit_lights_init) 1 = ||
	(S.L.cockpit_light_tachy_fail)

	(L.L.cockpit_board_warn) 1 = (L.L.elec_busbar_main) && (L.L.cockpit_lights_init) 1 = ||
	(S.L.cockpit_light_warning)

	(L.L.cockpit_board_critical) 1 = (L.L.elec_busbar_main) && (L.L.cockpit_lights_init) 1 = ||
	(S.L.cockpit_light_critical)
'
'
	(L.L.engine_tank_content) 35 < (L.L.elec_busbar_main) && (L.L.cockpit_lights_init) 1 = ||
	(S.L.cockpit_light_fuel)

	(L.L.engine_temperature) 100 > (L.L.elec_busbar_main) && (L.L.cockpit_lights_init) 1 = ||
	(S.L.cockpit_light_temp)
	(L.L.cockpit_light_notused_on) 1 = (L.L.elec_busbar_main) && (L.L.cockpit_lights_init) 1 = ||
	(S.L.cockpit_light_notused)
{endif}

(L.L.elec_busbar_main)
{if}
	(L.L.cp_driver_belt_sw) 0 =
	(L.L.Velocity) abs 10 > &&
	{if}
		1 (S.L.cockpit_driver_belt_alarm)
	{else}
		0 (S.L.cockpit_driver_belt_alarm)
	{endif}
{else}
	0 (S.L.cockpit_driver_belt_alarm)
{endif}

(L.L.elec_busbar_main) 1 = 
{if}
	(L.L.antrieb_getr_aktugang) -1 =
	{if}
		1 (S.L.cp_rear_cam_active)
	{else}
		(L.L.cp_rear_cam_active_sw) 1 =
		{if}
			1 (S.L.cp_rear_cam_active)
		{else}
			0 (S.L.cp_rear_cam_active)
		{endif}
	{endif}
{else}
	0 (S.L.cp_rear_cam_active)
{endif}

(L.L.elec_busbar_main)
{if}
	(L.L.cp_whe_btn_0_timer) (L.S.Timegap) + (S.L.cp_whe_btn_0_timer) 0.3 >
	(L.L.cp_whe_btn_0_rep) 0 = &&
	{if}

		1 (S.L.cp_whe_btn_0_rep)
		0 (S.L.cp_whe_btn_0_rep_trg)
		(L.L.cp_whe_btn_0_type) 1 =
		{if}
			(L.L.board_current) 5 <
			{if}
				(L.L.board_current) 1 + (S.L.board_current)
			{else}
				1 (S.L.board_current)
			{endif}
		{endif}

		(L.L.cp_whe_btn_0_type) 2 =
		{if}
			(L.L.board_current) 1 >
			{if}
				(L.L.board_current) 1 - (S.L.board_current)
			{else}
				5 (S.L.board_current)
			{endif}
		{endif}

	{endif}
{endif}

' Dashboard luminosity
'

'(L.L.cp_dash_luminosity_refresh) 1 =
'(L.L.lights_stand) 1 = &&
'	(L.L.cp_dash_luminosity) 0 =
'	{if}
'		"dash_on.png" (S.$.cp_dash_luminosity_intensity)
'	{endif}

'	(L.L.cp_dash_luminosity) 1 =
'	{if}
'		"dash_on_1.png" (S.$.cp_dash_luminosity_intensity)
'	{endif}

'	(L.L.cp_dash_luminosity) 2 =
'	{if}
'		"dash_on_2.png" (S.$.cp_dash_luminosity_intensity)
'	{endif}

'	(L.L.cp_dash_luminosity) 3 =
'	{if}
'		"dash_on_3.png" (S.$.cp_dash_luminosity_intensity)
'	{endif}

'	0 (S.L.cp_dash_luminosity_refresh)
'{endif}

	(L.L.cp_lightsw_rot_lastmode) (L.L.cp_lightsw_rot_mode) = !
	{if}
		(T.L.ev_light_sw)
	{endif}
	(L.L.cp_lightsw_rot_mode) (S.L.cp_lightsw_rot_lastmode)

	(L.L.lights_sw_blinker) 1 =
	{if}	
		-1 (S.L.cockpit_blinker_sw)
	{else}
		(L.L.lights_sw_blinker) 2 =
		{if}
			1 (S.L.cockpit_blinker_sw)
		{else}
			0 (S.L.cockpit_blinker_sw)
		{endif}
	{endif}


	(L.L.lights_sw_fern)
	{if}	
		(L.L.cockpit_fernlichthebel) -1 = !
		{if}
			1 (S.L.cockpit_fernlichthebel)
		{endif}

		(L.L.cp_lightsw_rot) 0.8 >
		{if}
			-1 (S.L.cockpit_fernlichthebel)
		{endif}
	{else}
		0 (S.L.cockpit_fernlichthebel)
	{endif}


	(M.L.rollo_elec_frame)
	(M.L.rollo1_frame)

{end}

{macro:CP_Lights_frame}
	(L.L.cp_elec_utilities) 1 =
	{if}
		1 (S.L.cp_elec_utilities_active)
	{else}
		0 (S.L.cp_elec_utilities_active)
	{endif}

	(L.L.elec_busbar_main)
	{if}
		(L.S.Time) 3600 / s6 trunc s7 "02" $IntToStrEnh ": " $+
		l6 l7 - 60 * trunc "02" $IntToStrEnh $+
		(S.$.cp_h_time)
	
		0 (S.L.cp_elec_utilities_timer)

		(L.L.lights_start_done) 1 =
		{if}
			(L.L.cp_lights_doors_sw) abs (S.L.cp_lights_doors_active)
			(L.L.cp_lights_ambiant_sw) abs (S.L.cp_lights_ambiant_active)
			(L.L.cp_lights_frontd_sw) abs (S.L.cp_lights_frontd_active)
			(L.L.cp_lights_driver_sw) abs (S.L.cp_lights_driver_active) (S.L.cp_lights_driver)
			(L.L.cp_lights_interior_sw) abs (S.L.cp_lights_interior_active)
			(L.L.cp_drvseat_heat_sw) abs (S.L.cp_drvseat_heat_active)
			(L.L.cp_defrost_sw) abs (S.L.cp_defrost_active)
			(L.L.cp_recycled_air_sw) abs (S.L.cp_recycled_air_active)
			(L.L.cp_pmr_avail_sw) abs (S.L.cp_pmr_avail_active)
			(L.L.cp_retarder_uncoupled_sw) abs (S.L.cp_retarder_uncoupled_active)
			(L.L.cp_fridge_sw) abs (S.L.cp_fridge_sw_active)
			(L.L.cp_hold_sw) abs (S.L.cp_hold_sw_active)
			(L.L.cp_asr_toggle_sw) abs (S.L.cockpit_asr_active)

			(L.L.cp_retarder_uncoupled_active) 1 =
			{if}
				1 (S.L.RetarderUncoupled)
			{else}
				0 (S.L.RetarderUncoupled)
			{endif}

			(L.L.cp_lights_interior_sw) 0 =
			{if}
				0 (S.L.cp_lights_int_2) (S.L.cp_lights_int_1) (S.L.cp_lights_int_3)

				0 (S.L.cp_lights_int_type)
			{else}
				(L.L.cp_lights_interior_sw) 1 =
				{if}
					0 (S.L.cp_lights_int_2)

					(L.L.vis_blue_ledx) 1 =
					{if}
						3 (S.L.cp_lights_int_type)
						1 (S.L.cp_lights_int_3)
					{else}
						1 (S.L.cp_lights_int_type)
						1 (S.L.cp_lights_int_1)
					{endif}
				{else}
					1 (S.L.cp_lights_int_2)
					2 (S.L.cp_lights_int_type)

					(L.L.vis_blue_ledx) 1 =
					{if}
						0 (S.L.cp_lights_int_3)
						1 (S.L.cp_lights_int_1)
						0 (S.L.vis_blue_led)
					{else}
						1 (S.L.cp_lights_int_1)
					{endif}
				{endif}
			{endif}

			(L.L.door_0) 0.1 >
			(L.L.cp_lights_frontd_active) 1 = &&
			{if}
				1 (S.L.cp_light_frontd)
			{else}
				0 (S.L.cp_light_frontd)
			{endif}

			(L.L.cp_rear_buzzer_sw) 0 =
			{if}
				1 (S.L.lights_reverse_buzzer)
			{else}
				0 (S.L.lights_reverse_buzzer)
			{endif}
		{else}
			0 (S.L.cp_lights_doors_active) (S.L.cockpit_asr_active) (S.L.cp_lights_ambiant_active) (S.L.cp_lights_frontd_active) (S.L.cp_lights_driver_active) (S.L.cp_lights_interior_active) (S.L.cp_light_frontd) (S.L.cp_lights_int_1) (S.L.cp_lights_int_2) (S.L.cp_lights_int_3) (S.L.cp_lights_driver) (S.L.cp_drvseat_heat_active) (S.L.cp_defrost_active) (S.L.cp_asr_toggle_active) (S.L.cp_recycled_air_active) (S.L.lights_reverse_buzzer) (S.L.cp_elec_utilities_active) (S.L.cp_pmr_avail_active) (S.L.cp_retarder_uncoupled_active) (S.L.cp_lights_int_type) (S.L.cp_fridge_sw_active) (S.L.cp_hold_sw_active)
		{endif}
	{else}
		0 (S.L.haltewunschlampe)
		"" (S.$.cp_h_time)
		0 (S.L.cp_lights_doors_active) (S.L.cockpit_asr_active) (S.L.cp_lights_ambiant_active) (S.L.cp_lights_frontd_active) (S.L.cp_lights_driver_active) (S.L.cp_lights_interior_active) (S.L.cp_light_frontd) (S.L.cp_lights_int_1) (S.L.cp_lights_int_2) (S.L.cp_lights_int_3) (S.L.cp_lights_driver) (S.L.cp_drvseat_heat_active) (S.L.cp_defrost_active) (S.L.cp_asr_toggle_active) (S.L.cp_recycled_air_active) (S.L.lights_reverse_buzzer) (S.L.cp_pmr_avail_active) (S.L.cp_retarder_uncoupled_active) (S.L.cp_lights_int_type) (S.L.cp_fridge_sw_active) (S.L.cp_hold_sw_active)

		(L.L.cp_elec_utilities_timer) 902 <
		{if}
			(L.L.cp_elec_utilities_timer) (L.S.Timegap) + (S.L.cp_elec_utilities_timer) 900 >
			{if}
				0 (S.L.cp_elec_utilities) (S.L.cp_elec_utilities_active)
			{endif}
		{endif}
	{endif}
{end}

{trigger:cp_wheel_key_drag}
	(L.S.mouse_y) -30 / (L.L.cp_wheel_key) + 0 max 1 min (S.L.cp_wheel_key) s1
	l1 0.2 <
		{if}
			0 (S.L.engine_injection_on) (S.L.engine_starter) (S.L.engine_on)

			(L.L.cp_emer_battery) 0 =
			(L.L.cp_batterietrennschalter_antirepeat) 0 = &&
			{if}
				1 (S.L.cp_batterietrennschalter_antirepeat)

				(L.L.elec_busbar_main_sw) !
				{if}
					-1 (S.L.cp_batterietrennschalter_sw)
					0 (S.L.cp_wheel_key_mode) (S.L.cp_wheel_key)
					0 (S.L.elec_busbar_main_sw)
					(T.L.ev_contact_off)
				{endif}
			{endif}
		{else} 
			l1 0.5 <
			{if}
				0 (S.L.engine_injection_on) (S.L.engine_starter) (S.L.engine_on)

				(L.L.cp_emer_battery) 0 =
				(L.L.cp_batterietrennschalter_antirepeat) 0 = &&
				{if}
					1 (S.L.cp_batterietrennschalter_antirepeat)

					(L.L.elec_busbar_main_sw)
					{if}
						0 (S.L.cp_batterietrennschalter_sw)
						0.5 (S.L.cp_wheel_key_mode) (S.L.cp_wheel_key)
						1 (S.L.elec_busbar_main_sw)
						1 (S.L.cp_elec_utilities)
						1 (S.L.cp_taster_batterietrennschalter)
						(T.L.ev_contact_on)
					{endif}
				{endif}
			{else}
				l1 0.8 <
				{if}
					0.8 (S.L.cp_wheel_key_mode)
				{else}
					(L.L.engine_on) ! (L.L.antrieb_getr_gangwahl) 1 = (L.L.elec_busbar_main) && &&
					{if}
						0.8 (S.L.cp_wheel_key_mode)

						(L.L.engine_starter) 0 =
						(L.L.cp_emer_battery) 0 = &&
						{if}
							(T.L.ev_engine_starter)
						{endif}

						(L.L.engine_started_once) 0 =
						(L.L.cp_emer_battery) 0 = &&
						{if}
							1 (S.L.engine_starter)
						{else}
							2 (S.L.engine_starter)
						{endif}
						1 (S.L.engine_injection_on)
					{endif}	
					(L.L.engine_on)
					{if}
						0.8 (S.L.cp_wheel_key_mode)
					{endif}
				{endif}	
			{endif}
		{endif}
	{endif}
{end}

{macro:Cockpit_Buttons_Lights}
	(L.L.elec_busbar_main)
	(L.L.lights_start_done) 1 = &&
	{if}

		(L.L.door_0) 0.05 <
		(L.L.door_2) 0.05 < &&
		{if}
			0 (S.L.cp_warning_doors_sw_active)
		{endif}
		(L.L.door_0) 0.05 >
		(L.L.door_2) 0.05 > ||
		{if}
			(L.L.cp_warning_doors_sw_disabled) 0 =
			{if}
				1 (S.L.cp_warning_doors_sw_active)
			{else}
				0 (S.L.cp_warning_doors_sw_active)
			{endif}
		{endif}
		(L.L.cp_warning_doors_sw_disabled) 0 =
		{if}
			0 (S.L.cp_warning_doors_sw_light)
		{else}
			1 (S.L.cp_warning_doors_sw_light)
		{endif}

		(L.L.door_0) 0.1 >
		{if}
			1 (S.L.cp_front_door_sw_light)
		{else}
			0 (S.L.cp_front_door_sw_light)
		{endif}

		(L.L.door_2) 0.1 >
		{if}
			1 (S.L.cp_rear_door_sw_light)
		{else}
			0 (S.L.cp_rear_door_sw_light)
		{endif}	

		(L.L.cp_brake_valve_bremse)
		{if}
			1 (S.L.cp_brake_valve_sw_light)
		{else}
			0 (S.L.cp_brake_valve_sw_light)
		{endif}

	{else}
		0 (S.L.cp_warning_doors_sw_light) (S.L.cp_front_door_sw_light) (S.L.cp_rear_door_sw_light) (S.L.cp_brake_valve_sw_light)
	{endif}
{end}



{trigger:cp_wheel_key_off}
	(L.L.cp_wheel_key_mode) (S.L.cp_wheel_key)
{end}

{trigger:kw_batterietrennschalter}
	(L.L.cp_batterietrennschalter_antirepeat) 0 =
	{if}
		1 (S.L.cp_taster_batterietrennschalter)
		1 (S.L.elec_busbar_main_sw)
		1 (S.L.cp_elec_utilities)
	{endif}
{end}

{trigger:kw_batterietrennschalter_off}
	0 (S.L.cp_taster_batterietrennschalter)
{end}

{trigger:cp_batterietrennschalter_toggle}
	(L.L.cp_emer_battery) 0 =
	(L.L.cp_batterietrennschalter_antirepeat) 0 = &&
	{if}
		1 (S.L.cp_batterietrennschalter_antirepeat)

		(L.L.elec_busbar_main_sw) !
		{if}
			0 (S.L.cp_batterietrennschalter_sw)
			0.5 (S.L.cp_wheel_key_mode) (S.L.cp_wheel_key)
			1 (S.L.elec_busbar_main_sw)
			1 (S.L.cp_elec_utilities)
			1 (S.L.cp_taster_batterietrennschalter)
			(T.L.ev_contact_on)
		{else}
			-1 (S.L.cp_batterietrennschalter_sw)
			0 (S.L.cp_wheel_key_mode) (S.L.cp_wheel_key)
			0 (S.L.elec_busbar_main_sw)
			(T.L.ev_contact_off)
		{endif}
	{endif}
{end}

{trigger:cp_batterietrennschalter_toggle_off}
	0 (S.L.cp_taster_batterietrennschalter) (S.L.cp_batterietrennschalter_antirepeat)
{end}

{trigger:cp_emer_battery_toggle}
	(L.L.cp_emer_battery_antirepeat) 0 =
	{if}
		1 (S.L.cp_emer_battery_antirepeat)

		(L.L.cp_emer_battery) 0 =
		{if}
			0 (S.L.elec_busbar_main_sw) (S.L.engine_injection_on) (S.L.engine_starter) (S.L.engine_on)
			-1 (S.L.cp_emer_battery_sw)
			(S.L.cp_emer_battery)
			(T.L.ev_btn_on)
			0 (S.L.cp_elec_utilities)
		{else}
			0 (S.L.cp_emer_battery_sw) (S.L.cp_emer_battery)
			(T.L.ev_btn_off)
		{endif}
	{endif}
{end}

{trigger:cp_emer_battery_toggle_off}
	0 (S.L.cp_emer_battery_antirepeat)
{end}

{trigger:cp_defrost_mirrors}
	(L.L.cp_defrost_mirrors_sw) 0 =
	{if}
		1 (S.L.cp_defrost_mirrors_sw)
		(T.L.ev_btn_on)
	{else}
		0 (S.L.cp_defrost_mirrors_sw)
		(T.L.ev_btn_off)
	{endif}
{end}

{trigger:cp_defrost_door}
	(L.L.cp_defrost_door_sw) 0 =
	{if}
		1 (S.L.cp_defrost_door_sw)
		(T.L.ev_btn_on)
	{else}
		0 (S.L.cp_defrost_door_sw)
		(T.L.ev_btn_off)
	{endif}
{end}

{trigger:cp_doors_security}
	(L.L.cp_doors_security_sw) 0 =
	{if}
		1 (S.L.cp_doors_security_sw)
	{else}
		0 (S.L.cp_doors_security_sw)
	{endif}

	(T.L.ev_btn_switch)
{end}

{trigger:cp_doors_security_sw_obj}
	(L.L.cp_doors_security_obj) 0 =
	{if}
		1 (S.L.cp_doors_security_obj)
		(T.L.ev_btn_switch_obj_on)
	{else}
		0 (S.L.cp_doors_security_obj)
		(T.L.ev_btn_switch_obj_off)
	{endif}
{end}

{trigger:cp_ethyl_security}
	(L.L.cp_ethyl_security_sw) 0 =
	{if}
		1 (S.L.cp_ethyl_security_sw)
	{else}
		0 (S.L.cp_ethyl_security_sw)
	{endif}

	(T.L.ev_btn_switch)
{end}

{trigger:cp_ethyl_security_sw_obj}
	(L.L.cp_ethyl_security_obj) 0 =
	{if}
		1 (S.L.cp_ethyl_security_obj)
		(T.L.ev_btn_switch_obj_on)
	{else}
		0 (S.L.cp_ethyl_security_obj)
		(T.L.ev_btn_switch_obj_off)
	{endif}

	(T.L.ev_btn_switch_obj)
{end}

{trigger:cp_fridge}
	(L.L.cp_fridge_obj) 0 =
	{if}
		1 (S.L.cp_fridge_obj)
	{else}
		0 (S.L.cp_fridge_obj)
	{endif}
{end}

{trigger:cp_motor_hood}
	(L.L.cp_motor_hood_obj) 0 =
	{if}
		1 (S.L.cp_motor_hood_obj)
		(T.L.ev_motor_hood_on)
	{else}
		0 (S.L.cp_motor_hood_obj)
	{endif}
{end}

{trigger:cp_gazoil_valve}
	(L.L.cp_gazoil_valve_obj) 0 =
	{if}
		1 (S.L.cp_gazoil_valve_obj)
		(T.L.ev_valve_gazoil_on)
	{else}
		0 (S.L.cp_gazoil_valve_obj)
		(T.L.ev_valve_gazoil_off)
	{endif}
{end}

{trigger:cp_adblue_valve}
	(L.L.cp_adblue_valve_obj) 0 =
	{if}
		1 (S.L.cp_adblue_valve_obj)
		(T.L.ev_valve_adblue_on)
	{else}
		0 (S.L.cp_adblue_valve_obj)
		(T.L.ev_valve_adblue_off)
	{endif}
{end}

{trigger:cp_socket_1}
	(L.L.cp_socket_1_obj) 0 =
	{if}
		1 (S.L.cp_socket_1_obj)
	{else}
		0 (S.L.cp_socket_1_obj)
	{endif}
{end}

{trigger:cp_socket_2}
	(L.L.cp_socket_2_obj) 0 =
	{if}
		1 (S.L.cp_socket_2_obj)
	{else}
		0 (S.L.cp_socket_2_obj)
	{endif}
{end}

{trigger:cp_socket_3}
	(L.L.cp_socket_3_obj) 0 =
	{if}
		1 (S.L.cp_socket_3_obj)
	{else}
		0 (S.L.cp_socket_3_obj)
	{endif}
{end}

{trigger:cp_lights_front_fogs}
	1 (S.L.cp_lights_front_fogs_sw)
	(T.L.ev_btn_fog_on)
	(L.L.lights_front_fogs) 0 =
	{if}
		1 (S.L.lights_front_fogs)
	{else}
		0 (S.L.lights_front_fogs)
	{endif}
{end}

{trigger:cp_lights_front_fogs_off}
	0 (S.L.cp_lights_front_fogs_sw)
	(T.L.ev_btn_fog_off)
{end}

{trigger:cp_lights_rear_fogs}
	1 (S.L.cp_lights_rear_fogs_sw)
	(T.L.ev_btn_fog_on)
	(L.L.lights_rear_fogs) 0 =
	{if}
		1 (S.L.lights_rear_fogs)
	{else}
		0 (S.L.lights_rear_fogs)
	{endif}
{end}

{trigger:cp_lights_rear_fogs_off}
	0 (S.L.cp_lights_rear_fogs_sw)
	(T.L.ev_btn_fog_off)
{end}

{trigger:horn}
	(L.L.cockpit_hupe) ! (L.L.elec_busbar_main) &&
	{if}
		(T.L.ev_hupe_an)
	{endif}
	1 (S.L.cockpit_hupe)
{end}

{trigger:horn_off}	
	(L.L.cockpit_hupe) (L.L.elec_busbar_main) &&
	{if}
		(T.L.ev_hupe_aus)
	{endif}
	0 (S.L.cockpit_hupe)
{end}

{macro:hupe_frame}
	(L.L.elec_busbar_main)
	{if}
		(L.L.cockpit_hupe) 1 =
		{if}
			(L.L.cockpit_hupe_volume) 1 <
			{if}
				(L.L.cockpit_hupe_volume) (L.S.Timegap) 10 * + (S.L.cockpit_hupe_volume)
			{else}
				1 (S.L.cockpit_hupe_volume)
			{endif}
		{else}
			(L.L.cockpit_hupe_volume) 0 >
			{if}
				(L.L.cockpit_hupe_volume) (L.S.Timegap) 10 * - (S.L.cockpit_hupe_volume)
			{else}
				0 (S.L.cockpit_hupe_volume)
			{endif}
		{endif}
	{else}
		(L.L.cockpit_hupe_volume) 0 >
		{if}
			(L.L.cockpit_hupe_volume) (L.S.Timegap) 10 * - (S.L.cockpit_hupe_volume)
		{else}
			0 (S.L.cockpit_hupe_volume)
		{endif}
	{endif}	
{end}

{trigger:cp_whe_pos_lock}
	(L.L.cp_whe_pos_lock_sw) 0 =
	{if}
		1 (S.L.cp_whe_pos_lock_sw) (S.L.cp_whe_pos_lock)
		
		(L.L.cockpit_alarm_pressure) 0 =
		{if}
			(T.L.ev_whe_on)
		{endif}
	{else}
		0 (S.L.cp_whe_pos_lock_sw) (S.L.cp_whe_pos_lock)
		(L.L.cockpit_alarm_pressure) 0 =
		{if}
			(T.L.ev_whe_off)
		{endif}
	{endif}
{end}

{trigger:cp_whe_pos_drag}
	(L.L.cp_whe_pos_lock) 1 =
	{if}
		(L.S.mouse_y) abs (L.S.mouse_x) abs >=
		{if}
			(L.S.mouse_y) 400 / (L.L.cp_whe_pos_trans) + 0 max 0.4 min (S.L.cp_whe_pos_trans)
		{else}
			(L.S.mouse_x) -400 / (L.L.cp_whe_pos_rot) + 0 max 0.2 min (S.L.cp_whe_pos_rot)
		{endif}
	{endif}
{end}

{trigger:cp_whe_btn_0_0}
	-1 (S.L.cp_whe_btn_0_sw)
	(T.L.ev_whe_btn_on)
	(L.L.cp_whe_btn_0_rep_trg) 0 =
	{if}
		0 (S.L.cp_whe_btn_0_timer) (S.L.cp_whe_btn_0_rep)
		1 (S.L.cp_whe_btn_0_type)
		1 (S.L.cp_whe_btn_0_rep_trg)
	{endif}
{end}

{trigger:cp_whe_btn_0_0_off}
	0 (S.L.cp_whe_btn_0_sw)
	(T.L.ev_whe_btn_off)
{end}

{trigger:cp_whe_btn_0_1}
	1 (S.L.cp_whe_btn_0_sw)
	(T.L.ev_whe_btn_on)
	(L.L.cp_whe_btn_0_rep_trg) 0 =
	{if}
		0 (S.L.cp_whe_btn_0_timer) (S.L.cp_whe_btn_0_rep)
		2 (S.L.cp_whe_btn_0_type)
		1 (S.L.cp_whe_btn_0_rep_trg)
	{endif}
{end}

{trigger:cp_whe_btn_0_1_off}
	0 (S.L.cp_whe_btn_0_sw)
	(T.L.ev_whe_btn_off)
{end}

{trigger:cp_whe_btn_4}
	1 (S.L.cp_whe_btn_4_sw)
	(T.L.ev_whe_btn_on)
{end}

{trigger:cp_whe_btn_4_off}
	0 (S.L.cp_whe_btn_4_sw)
	(T.L.ev_whe_btn_off)
{end}


{trigger:cp_whe_vis_trg}
	(L.L.cp_whe_vis) 0 =
	{if}
		1 (S.L.cp_whe_vis)
	{else}
		0 (S.L.cp_whe_vis)
	{endif}
{end}

{trigger:cp_trip_km_1_reset}
	1 (S.L.cp_trip_km_1_sw)
	0 (S.L.cp_trip_km_1)
	(L.L.kmcounter_km) (S.L.cp_trip_km_1_reset_state)
	(L.L.engine_tank_content) (S.L.cp_trip_fuel_1_reset_state)
	0 (S.L.cp_trip_time_1_since_reset)
{end}

{trigger:cp_trip_km_1_reset_off}
	0 (S.L.cp_trip_km_1_sw)
{end}

{trigger:cp_dash_luminosity_change}
	1 (S.L.cp_dash_luminosity_sw) (S.L.cp_dash_luminosity_refresh)

	(L.L.cp_dash_luminosity) 1 + s0

	l0 4 <
	{if}
		(L.L.cp_dash_luminosity) 1 + (S.L.cp_dash_luminosity)
	{endif}

	l0 3 >
	{if}
		0 (S.L.cp_dash_luminosity)
	{endif}
{end}

{trigger:cp_dash_luminosity_change_off}
	0 (S.L.cp_dash_luminosity_sw)
{end}


{trigger:cp_rollo_up_drag}
	-1 (S.L.cp_rollo_sw)
	(L.L.elec_busbar_main)
	{if}
		1 (S.L.cp_rollo_active)
		(L.L.cp_rollo_pos) (L.S.Timegap) 0.3 * - (S.L.cp_rollo_pos)
		0 <
		{if}
			0 (S.L.cp_rollo_pos)
		{endif}
	{endif}
{end}

{trigger:cp_rollo_up_off}
	0 (S.L.cp_rollo_sw) (S.L.cp_rollo_active)
	(T.L.ev_btn_off)
{end}

{trigger:cp_rollo_up}
	(T.L.ev_btn_on)
{end}

{trigger:cp_rollo_down}
	(T.L.ev_btn_on)
{end}

{trigger:cp_rollo_down_drag}
	1 (S.L.cp_rollo_sw)
	(L.L.elec_busbar_main)
	{if}
		1 (S.L.cp_rollo_active)
		(L.L.cp_rollo_pos) (L.S.Timegap) 0.3 * + (S.L.cp_rollo_pos)
		1 >
		{if}
			1 (S.L.cp_rollo_pos)
		{endif}
	{endif}
{end}

{trigger:cp_rollo_down_off}
	0 (S.L.cp_rollo_sw) (S.L.cp_rollo_active)
	(T.L.ev_kippschalter_aus)
	(T.L.ev_btn_off)
{end}


{macro:rollo_elec_frame}
	(L.L.cp_rollo_pos) 0.914 >
	{if}
	1 (S.L.cp_rollo_1_visible) (S.L.cp_rollo_2_visible) (S.L.cp_rollo_3_visible) (S.L.cp_rollo_4_visible) (S.L.cp_rollo_5_visible) (S.L.cp_rollo_6_visible) 
	{else}
		(L.L.cp_rollo_pos) 0.590 >
		{if}
			1 (S.L.cp_rollo_1_visible) (S.L.cp_rollo_2_visible) (S.L.cp_rollo_3_visible) (S.L.cp_rollo_4_visible) (S.L.cp_rollo_5_visible) (S.L.cp_rollo_6_visible)
		{else}
			(L.L.cp_rollo_pos) 0.440 >
			{if}
				1 (S.L.cp_rollo_1_visible) (S.L.cp_rollo_2_visible) (S.L.cp_rollo_3_visible) (S.L.cp_rollo_4_visible) (S.L.cp_rollo_5_visible)
				0 (S.L.cp_rollo_6_visible)
			{else}
			(L.L.cp_rollo_pos) 0.312 >
			{if}
				1 (S.L.cp_rollo_1_visible) (S.L.cp_rollo_2_visible) (S.L.cp_rollo_3_visible) (S.L.cp_rollo_4_visible)
				0 (S.L.cp_rollo_5_visible) (S.L.cp_rollo_6_visible)
			{else}
			(L.L.cp_rollo_pos) 0.211 >
			{if}
				1 (S.L.cp_rollo_1_visible) (S.L.cp_rollo_2_visible) (S.L.cp_rollo_3_visible) 
				0 (S.L.cp_rollo_4_visible) (S.L.cp_rollo_5_visible) (S.L.cp_rollo_6_visible)
			{else}
			(L.L.cp_rollo_pos) 0.112 >
			{if}
				1 (S.L.cp_rollo_1_visible) (S.L.cp_rollo_2_visible)
				0 (S.L.cp_rollo_3_visible) (S.L.cp_rollo_4_visible) (S.L.cp_rollo_5_visible) (S.L.cp_rollo_6_visible)
			{else}
			(L.L.cp_rollo_pos) 0.014 >
			{if}
				1 (S.L.cp_rollo_1_visible)
				0 (S.L.cp_rollo_2_visible) (S.L.cp_rollo_3_visible) (S.L.cp_rollo_4_visible) (S.L.cp_rollo_5_visible) (S.L.cp_rollo_6_visible)
			{else}
			0 (S.L.cp_rollo_1_visible) (S.L.cp_rollo_2_visible) (S.L.cp_rollo_3_visible) (S.L.cp_rollo_4_visible) (S.L.cp_rollo_5_visible) (S.L.cp_rollo_6_visible)
			{endif}
			{endif}
		{endif}
		{endif}
		{endif}
		{endif}
	{endif}
{end}



{macro:rollo1_frame}
	(L.L.cp_rollo1_pos) (L.L.cp_rollo1_rastpos) max (S.L.cp_rollo1_rastpos)

	(L.L.cp_rollo1_dragged) !
	{if}
		(L.L.cp_rollo1_retract)
		{if}
			(L.L.cp_rollo1_speed) (L.S.Timegap) (L.L.cp_rollo1_pos) 14 * * - (S.L.cp_rollo1_speed)
			(L.L.cp_rollo1_pos) (L.S.Timegap) (L.L.cp_rollo1_speed) * + (S.L.cp_rollo1_pos) (S.L.cp_rollo1_rastpos)
					
		{else}
			(L.L.cp_rollo1_pos) (L.L.cp_rollo1_rastpos) < 
			{if}
				(L.L.cp_rollo1_speed) (L.S.Timegap) 14 * + (S.L.cp_rollo1_speed)
				(L.L.cp_rollo1_pos) (L.S.Timegap) (L.L.cp_rollo1_speed) * + (L.L.cp_rollo1_rastpos) min (S.L.cp_rollo1_pos)
			{else}
				0 (S.L.cp_rollo1_speed)
			{endif}
		{endif}

		(L.L.cp_rollo1_pos) 1 >
		{if}
			1 (S.L.cp_rollo1_pos) (S.L.cp_rollo1_rastpos)
		{else}
			(L.L.cp_rollo1_pos) 0 <
			{if}
			0 (S.L.cp_rollo1_pos) (S.L.cp_rollo1_retract) (S.L.cp_rollo1_rastpos)
			{endif}
		{endif}
	{endif}

	(L.L.cp_rollo1_pos) 0.4 <=
	{if}
		0 (S.L.cp_rollo1_vis)
	{endif}
	
	(L.L.cp_rollo1_pos) 0.4 >
	{if}
		1 (S.L.cp_rollo1_vis)
	{endif}
{end}

{trigger:cp_rollo1_drag}

	(L.L.cp_rollo1_pos) (S.L.cp_rollo1_lastpos)

	1 (S.L.cp_rollo1_dragged)
	0 (S.L.cp_rollo1_speed)
	(L.S.mouse_y) 500 / (L.L.cp_rollo1_pos) + (S.L.cp_rollo1_pos) s0
	l0 0 <
	{if}
		0 (S.L.cp_rollo1_pos)
	{endif}
	l0 1 >
	{if}
		1 (S.L.cp_rollo1_pos)
	{endif}

	(L.L.cp_rollo1_pos) (L.L.cp_rollo1_lastpos) - abs (L.S.Timegap) / (S.L.cp_rollo1_speed)

{end}

{trigger:cp_rollo1_off}
	0 (S.L.cp_rollo1_dragged)
	(T.L.ev_rollo1_end)
{end}

{trigger:cp_rollo1_retract}
	(L.L.cp_rollo1_bommel) 0 = (L.L.cp_rollo1_pos) &&
	{if}
		(T.L.ev_rollo1_retract)
	{endif}
	1 (S.L.cp_rollo1_bommel) (S.L.cp_rollo1_retract)

{end}

{trigger:cp_rollo1_retract_off}
	0 (S.L.cp_rollo1_bommel) (S.L.cp_rollo1_retract) (S.L.cp_rollo1_speed)
{end}


{trigger:cp_window_open_drag}
	1 (S.L.cp_window_sw)
	(L.L.elec_busbar_main)
	{if}
		1 (S.L.cp_window_active)
		(L.L.cp_window_pos) (L.S.Timegap) 0.4 * - (S.L.cp_window_pos)
		0 <
		{if}
			0 (S.L.cp_window_pos)
			(L.L.cp_window_pos) < 0.05
			(L.L.cp_window_a_rep) 0 = &&
			{if}
				1 (S.L.cp_window_a_rep)
				(T.L.ev_window_driver_open)
			{endif}
		{endif}
	{endif}
{end}

{trigger:cp_window_open_off}
	0 (S.L.cp_window_sw) (S.L.cp_window_active) (S.L.cp_window_a_rep)
	(T.L.ev_btn_off)
{end}

{trigger:cp_window_open}
	(T.L.ev_btn_on)
{end}

{trigger:cp_window_close}
	(T.L.ev_btn_on)
{end}

{trigger:cp_window_close_drag}
	-1 (S.L.cp_window_sw)
	(L.L.elec_busbar_main)
	{if}
		2 (S.L.cp_window_active)
		(L.L.cp_window_pos) (L.S.Timegap) 0.4 * + (S.L.cp_window_pos)
		1 >
		{if}
			1 (S.L.cp_window_pos)
			
			(L.L.cp_window_pos) > 0.95
			(L.L.cp_window_a_rep) 0 = &&
			{if}
				1 (S.L.cp_window_a_rep)
				(T.L.ev_window_driver_close)
			{endif}
		{endif}
	{endif}
{end}

{trigger:cp_window_close_off}
	0 (S.L.cp_window_sw) (S.L.cp_window_active) (S.L.cp_window_a_rep)
	(T.L.ev_btn_off)
{end}


{trigger:cp_driver_belt}
	(L.L.cp_driver_belt_sw) 0 =
	{if}
		1 (S.L.cp_driver_belt_sw)
		(T.L.ev_belt_on)
	{else}
		0 (S.L.cp_driver_belt_sw)
		(T.L.ev_belt_off)
	{endif}
{end}

{trigger:cp_driver_armset}
	(L.L.cp_driver_armset_sw) 0 =
	{if}
		1 (S.L.cp_driver_armset_sw)
	{else}
		0 (S.L.cp_driver_armset_sw)
	{endif}
{end}


{trigger:cp_warning_doors}
	(T.L.ev_btn_on)

	(L.L.cp_warning_doors_sw) 0 =
	{if}
		-1 (S.L.cp_warning_doors_sw)
		1 (S.L.cp_warning_doors_sw_disabled)
	{else}
		0 (S.L.cp_warning_doors_sw)
		0 (S.L.cp_warning_doors_sw_disabled)	
	{endif}
{end}

{trigger:cp_warning_doors_off}
	(T.L.ev_btn_off)
{end}

{trigger:cp_front_door_open}
	-1 (S.L.cp_front_door_sw)
	(L.L.elec_busbar_main)
	(L.L.cp_front_door_sw_repeat) 0 = &&
	{if}
		(L.L.throttle) 0.1 <
		(L.L.Velocity) 5 < &&
		(L.L.Velocity) -1 > &&
		{if}
			1 (S.L.cp_front_door_sw_repeat)
			(M.L.trg_bus_doorfront0)
		{endif}
	{else}
		(T.L.ev_btn_f_door_off)
	{endif}
	(T.L.ev_btn_on)
{end}

{trigger:cp_front_door_open_off}
	0 (S.L.cp_front_door_sw)
	(T.L.ev_btn_off)
{end}

{trigger:cp_front_door_close}
	1 (S.L.cp_front_door_sw)
	(L.L.elec_busbar_main)
	(L.L.cp_front_door_sw_repeat) 1 = &&
	{if}
		(L.L.Velocity) 5 <
		(L.L.Velocity) -1 > &&
		{if}
			0 (S.L.cp_front_door_sw_repeat)
			(M.L.trg_bus_doorfront0)
		{endif}
	{else}
		(T.L.ev_btn_f_door_off)
	{endif}
	(T.L.ev_btn_on)
{end}

{trigger:cp_front_door_close_off}
	0 (S.L.cp_front_door_sw)
	(T.L.ev_btn_off)
{end}

{trigger:cp_rear_door_open}
	-1 (S.L.cp_rear_door_sw)

	(L.L.elec_busbar_main)
    (L.L.door_2) 0.05 < &&
	(L.L.doorTarget_1) 0.5 < &&
    {if}
		(L.L.throttle) 0.1 <
		(L.L.Velocity) 5 < &&
		(L.L.Velocity) -1 > &&
		{if}
			0 (S.L.door_rear_repeat_primary) (S.L.door_rear_repeat_second)
        	1 (S.L.door1_mode)
		{endif}
	{else}
		(T.L.ev_btn_r_doors_off)
    {endif}
	(T.L.ev_btn_on)
{end}

{trigger:cp_rear_door_open_off}
	0 (S.L.cp_rear_door_sw)
	(T.L.ev_btn_off)
{end}

{trigger:cp_rear_door_close}
	1 (S.L.cp_rear_door_sw)

	(L.L.elec_busbar_main)
    (L.L.door_2) 0.1 > &&
	(L.L.doorTarget_1) 0.5 > &&
    {if}
		(L.L.Velocity) 5 <
		(L.L.Velocity) -1 > &&
		{if}
			0 (S.L.door_rear_repeat_primary) (S.L.door_rear_repeat_second)
			0 (S.L.cp_rear_door_sw_repeat)
        	2 (S.L.door1_mode)
		{endif}
	{else}
		(T.L.ev_btn_r_doors_off)
    {endif}
	(T.L.ev_btn_on)
{end}

{trigger:cp_rear_door_close_off}
	0 (S.L.cp_rear_door_sw)
	(T.L.ev_btn_off)
{end}


{trigger:cp_speed_limiter}
	-1 (S.L.cp_speed_limiter_sw)
	(T.L.ev_btn_on)

	(L.L.elec_busbar_main)
	(L.L.LimiterType) 0 = &&
	{if}
		0 (S.L.InjectionLocked)
		(L.L.antrieb_getr_aktugang) 1 >
		(L.L.Velocity) 25 > &&
		(L.L.Velocity) 102 < &&
		{if}
			1 (S.L.LimiterType)
			0 (S.L.CruiseActive)
			
			(L.L.Velocity) 20 >
			(L.L.Velocity) 30 < &&
			{if}
				30 (S.L.LimiterMax)
			{endif}
			(L.L.Velocity) 30 >
			(L.L.Velocity) 40 < &&
			{if}
				40 (S.L.LimiterMax)
			{endif}
			(L.L.Velocity) 40 >
			(L.L.Velocity) 50 < &&
			{if}
				50 (S.L.LimiterMax)
			{endif}
			(L.L.Velocity) 50 >
			(L.L.Velocity) 60 < &&
			{if}
				60 (S.L.LimiterMax)
			{endif}
			(L.L.Velocity) 60 >
			(L.L.Velocity) 70 < &&
			{if}
				70 (S.L.LimiterMax)
			{endif}
			(L.L.Velocity) 70 >
			(L.L.Velocity) 80 < &&
			{if}
				80 (S.L.LimiterMax)
			{endif}
			(L.L.Velocity) 80 >
			(L.L.Velocity) 90 < &&
			{if}
				90 (S.L.LimiterMax)
			{endif}
			(L.L.Velocity) 90 >
			(L.L.Velocity) 100 < &&
			{if}
				100 (S.L.LimiterMax)
			{endif}
		{endif}
	{else}
		0 (S.L.LimiterType)
	{endif}
{end}

{trigger:cp_speed_limiter_off}
	(T.L.ev_btn_off)
	0 (S.L.cp_speed_limiter_sw)
{end}


{trigger:cp_brake_valve}
	-1 (S.L.cp_brake_valve_sw)
	(T.L.ev_btn_on)

	(M.L.trg_door_bremse)
{end}

{trigger:cp_brake_valve_off}
	(T.L.ev_btn_off)
	0 (S.L.cp_brake_valve_sw)
{end}


{trigger:cp_lights_hold}
	(L.L.cp_lights_hold_sw) 0 =
	{if}
		-1 (S.L.cp_lights_hold_sw)
		(T.L.ev_btn_on)
	{else}
		0 (S.L.cp_lights_hold_sw)
		(T.L.ev_btn_off)
	{endif}
{end}

{trigger:cp_lights_doors}
	(L.L.cp_lights_doors_sw) 0 =
	{if}
		-1 (S.L.cp_lights_doors_sw)
		(T.L.ev_btn_on)
	{else}
		0 (S.L.cp_lights_doors_sw)
		(T.L.ev_btn_off)
	{endif}
{end}

{trigger:cp_lights_ambiant}
	(L.L.cp_lights_ambiant_sw) 0 =
	{if}
		-1 (S.L.cp_lights_ambiant_sw)
		(T.L.ev_btn_on)
	{else}
		0 (S.L.cp_lights_ambiant_sw)
		(T.L.ev_btn_off)
	{endif}
{end}

{trigger:cp_lights_frontd}
	(L.L.cp_lights_frontd_sw) 0 =
	{if}
		-1 (S.L.cp_lights_frontd_sw)
		(T.L.ev_btn_on)
	{else}
		0 (S.L.cp_lights_frontd_sw)
		(T.L.ev_btn_off)
	{endif}
{end}

{trigger:cp_lights_driver}
	(L.L.cp_lights_driver_sw) 0 =
	{if}
		-1 (S.L.cp_lights_driver_sw)
		(T.L.ev_btn_on)
	{else}
		0 (S.L.cp_lights_driver_sw)
		(T.L.ev_btn_off)
	{endif}
{end}

{trigger:cp_lights_int_up}
	(L.L.cp_lights_interior_sw) 0 =
	{if}
		-1 (S.L.cp_lights_interior_sw)
		(T.L.ev_btn_on)
	{else}
		0 (S.L.cp_lights_interior_sw)
		(T.L.ev_btn_off)
	{endif}
{end}

{trigger:cp_lights_int_down}
	(L.L.cp_lights_interior_sw) 0 =
	{if}
		1 (S.L.cp_lights_interior_sw)
		(T.L.ev_btn_on)
	{else}
		0 (S.L.cp_lights_interior_sw)
		(T.L.ev_btn_off)
	{endif}
{end}

{trigger:cp_drvseat_heat}
	(L.L.cp_drvseat_heat_sw) 0 =
	{if}
		-1 (S.L.cp_drvseat_heat_sw)
		(T.L.ev_btn_on)
	{else}
		0 (S.L.cp_drvseat_heat_sw)
		(T.L.ev_btn_off)
	{endif}
{end}

{trigger:cp_rear_buzzer}
	(L.L.cp_rear_buzzer_sw) 0 =
	{if}
		-1 (S.L.cp_rear_buzzer_sw)
		(T.L.ev_btn_on)
	{else}
		0 (S.L.cp_rear_buzzer_sw)
		(T.L.ev_btn_off)
	{endif}
{end}

{trigger:cp_defrost}
	(L.L.cp_defrost_sw) 0 =
	{if}
		-1 (S.L.cp_defrost_sw)
		(T.L.ev_btn_on)
	{else}
		0 (S.L.cp_defrost_sw)
		(T.L.ev_btn_off)
	{endif}
{end}

{trigger:cp_asr_toggle}
	(L.L.cp_asr_toggle_sw) 0 =
	{if}
		-1 (S.L.cp_asr_toggle_sw)
		(T.L.ev_btn_on)
	{else}
		0 (S.L.cp_asr_toggle_sw)
		(T.L.ev_btn_off)
	{endif}
{end}

{trigger:cp_recycled_air}
	(L.L.cp_recycled_air_sw) 0 =
	{if}
		-1 (S.L.cp_recycled_air_sw)
		(T.L.ev_btn_on)
	{else}
		0 (S.L.cp_recycled_air_sw)
		(T.L.ev_btn_off)
	{endif}
{end}

{trigger:cp_elec_utilities}
	(T.L.ev_btn_on)
	-1 (S.L.cp_elec_utilities_sw)

	(L.L.cp_elec_utilities) 0 =
	{if}
		(L.L.elec_busbar_main) 1 =
		{if}
			1 (S.L.cp_elec_utilities)
		{endif}
	{else}
		0 (S.L.cp_elec_utilities)
	{endif}
{end}

{trigger:cp_elec_utilities_off}
	0 (S.L.cp_elec_utilities_sw)
	(T.L.ev_btn_off)
{end}

{trigger:cp_pmr_avail}
	(L.L.cp_pmr_avail_sw) 0 =
	{if}
		-1 (S.L.cp_pmr_avail_sw)
		(T.L.ev_btn_on)
	{else}
		0 (S.L.cp_pmr_avail_sw)
		(T.L.ev_btn_off)
	{endif}
{end}

{trigger:cp_retarder_uncoupled}
	(L.L.cp_retarder_uncoupled_sw) 0 =
	{if}
		-1 (S.L.cp_retarder_uncoupled_sw)
		(T.L.ev_btn_on)
	{else}
		0 (S.L.cp_retarder_uncoupled_sw)
		(T.L.ev_btn_off)
	{endif}
{end}

{trigger:cp_susp_up}
	(T.L.ev_btn_on)
	-1 (S.L.cp_susp_level_sw)

	(L.L.elec_busbar_main)
	(L.L.cockpit_alarm_pressure) 0 = &&
	(L.L.Velocity) 10 < &&
	(L.L.Velocity) -1 > &&
	{if}
		0.01 (S.L.bremse_level_setpoint)
		1 (S.L.cp_susp_mode)
	{endif}
{end}

{trigger:cp_susp_up_off}
	0 (S.L.cp_susp_level_sw)
	(T.L.ev_btn_off)
{end}

{trigger:cp_susp_dw}
	(T.L.ev_btn_on)
	1 (S.L.cp_susp_level_sw)

	(L.L.elec_busbar_main)
	(L.L.cockpit_alarm_pressure) 0 = &&
	(L.L.Velocity) 5 < &&
	(L.L.Velocity) -1 > &&
	{if}
		-0.22 (S.L.bremse_level_setpoint)
		2 (S.L.cp_susp_mode)
	{endif}
{end}

{trigger:cp_susp_dw_off}
	0 (S.L.cp_susp_level_sw)
	(T.L.ev_btn_off)
{end}

{trigger:cp_susp_reset}
	(T.L.ev_btn_on)

	(L.L.elec_busbar_main)
	(L.L.cockpit_alarm_pressure) 0 = &&
	{if}
		1 (S.L.cp_susp_reset_sw)
		(C.L.bremse_level_setpoint) (S.L.bremse_level_setpoint)
		0 (S.L.cp_susp_mode)
	{endif}
{end}

{trigger:cp_susp_reset_off}
	0 (S.L.cp_susp_reset_sw)
	(T.L.ev_btn_off)
{end}

{trigger:cp_susp_emergency}
	(L.L.elec_busbar_main)
	{if}
		(T.L.ev_btn_on)
		1 (S.L.cp_susp_emergency_sw)
		(C.L.bremse_level_setpoint) (S.L.bremse_level_setpoint)
		0 (S.L.cp_susp_mode)
	{endif}
{end}

{trigger:cp_susp_emergency_off}
	0 (S.L.cp_susp_emergency_sw)
	(T.L.ev_btn_off)
{end}

{trigger:cp_front_fogs}
	-1 (S.L.cp_front_fogs_sw)
	(T.L.ev_btn2_on)

	(L.L.elec_busbar_main)
	{if}
		(L.L.cp_front_fogs_enabled) 0 =
		{if}
			1 (S.L.cp_front_fogs_enabled)
		{else}
			0 (S.L.cp_front_fogs_enabled)
		{endif}
	{endif}
{end}

{trigger:cp_front_fogs_off}
	(T.L.ev_btn2_off)
	0 (S.L.cp_front_fogs_sw)
{end}

{trigger:cp_rear_fogs}
	-1 (S.L.cp_rear_fogs_sw)
	(T.L.ev_btn2_on)

	(L.L.elec_busbar_main)
	{if}
		(L.L.cp_rear_fogs_enabled) 0 =
		{if}
			1 (S.L.cp_rear_fogs_enabled)
		{else}
			0 (S.L.cp_rear_fogs_enabled)
		{endif}
	{endif}
{end}

{trigger:cp_rear_fogs_off}
	(T.L.ev_btn2_off)
	0 (S.L.cp_rear_fogs_sw)
{end}

{trigger:cp_blink_warning}
	-1 (S.L.cp_blink_warning_sw)
	(T.L.ev_btn3_on)

	(L.L.elec_busbar_main)
	{if}
		(L.L.lights_sw_warnblinker) 0 =
		{if}
			1 (S.L.lights_sw_warnblinker)
		{else}
			0 (S.L.lights_sw_warnblinker)
		{endif}
	{endif}
{end}

{trigger:cp_blink_warning_off}
	(T.L.ev_btn3_off)
	0 (S.L.cp_blink_warning_sw)
{end}

{trigger:cp_fridge_btn}
	(L.L.cp_fridge_sw) 0 =
	{if}
		-1 (S.L.cp_fridge_sw)
		(T.L.ev_btn_on)
	{else}
		0 (S.L.cp_fridge_sw)
		(T.L.ev_btn_off)
	{endif}
{end}

{trigger:cp_hold}
	(L.L.cp_hold_sw) 0 =
	{if}
		-1 (S.L.cp_hold_sw)
		(T.L.ev_btn_on)
	{else}
		0 (S.L.cp_hold_sw)
		(T.L.ev_btn_off)
	{endif}
{end}

{trigger:cp_rear_cam}
	(L.L.elec_busbar_main)
	{if}
		(L.L.cp_rear_cam_active_sw) 0 =
		{if}
			1 (S.L.cp_rear_cam_active_sw)
		{else}
			0 (S.L.cp_rear_cam_active_sw)
		{endif}
	{endif}
{end}

{trigger:cp_wischer_schnell_toggle}
	(L.L.cp_wischer_schnell_sw) ! (S.L.cp_wischer_schnell_sw) s1
{end}

{trigger:kw_wipermode_up}
	(L.L.cp_wischer_einaus_sw) ! (S.L.cp_wischer_einaus_sw) s1
	{if}
		2 (S.L.cockpit_wischerhebel_mode) (S.L.cockpit_wischer_drehschalter_mode)
		2 3 / (S.L.cockpit_wischerhebel) (S.L.cockpit_wischer_drehschalter)
		(L.L.cp_wischer_intervall_sw) !
		{if}
			(T.L.ev_wischerhebel)
		{endif}
	{else}
		(L.L.cp_wischer_intervall_sw)
		{if}
			1 (S.L.cockpit_wischerhebel_mode) (S.L.cockpit_wischer_drehschalter_mode)
			1 3 / (S.L.cockpit_wischerhebel) 
			0 (S.L.cockpit_wischer_drehschalter)
		{else}
			0 (S.L.cockpit_wischerhebel_mode) (S.L.cockpit_wischer_drehschalter_mode) (S.L.cockpit_wischerhebel) 
			1 3 / (S.L.cockpit_wischer_drehschalter)
			(T.L.ev_wischerhebel)
		{endif}
	{endif}
{end}

{trigger:cp_wischer_intervall_toggle}
	(L.L.cp_wischer_intervall_sw) ! (S.L.cp_wischer_intervall_sw) s1
	(L.L.cp_wischer_einaus_sw) ! &&
	{if}
		1 (S.L.cockpit_wischerhebel_mode) (S.L.cockpit_wischer_drehschalter_mode)
		1 3 / (S.L.cockpit_wischerhebel) 
		0 (S.L.cockpit_wischer_drehschalter)
	{else}
		(L.L.cp_wischer_einaus_sw)
		{if}
			2 (S.L.cockpit_wischerhebel_mode) (S.L.cockpit_wischer_drehschalter_mode)
			2 3 / (S.L.cockpit_wischerhebel) (S.L.cockpit_wischer_drehschalter)
		{else}
			0 (S.L.cockpit_wischerhebel_mode) (S.L.cockpit_wischer_drehschalter_mode) (S.L.cockpit_wischerhebel)
			1 3 / (S.L.cockpit_wischer_drehschalter)
		{endif}

	{endif}
{end}

{trigger:cp_wischer_wascher_button}
	1 (S.L.cp_wischer_wascher_sw) s1
	(C.L.wiper_lever)
	{if}
		(T.L.ev_wischerhebel)
		1 (S.L.cockpit_wischerhebel_x)
	{endif}
{end}

{trigger:cp_wischer_wascher_button_off}
	0 (S.L.cp_wischer_wascher_sw) s1
	(S.L.wiper_wascher_sw)
	(C.L.wiper_lever)
	{if}
		(T.L.ev_wischerhebel)
		0 (S.L.cockpit_wischerhebel_x)
	{endif}
{end}

{trigger:cp_wiper_turnswitch_drag}

'	(C.L.wiper_turnswitch)
'	{if}
	
		(L.S.mouse_y) -50 / (L.L.cockpit_wischer_drehschalter) + 0 max 1 min (S.L.cockpit_wischer_drehschalter) s0
	
'		Stufen:
'		0: Intervall
'		1: Aus
'		2: Langsam
'		3: Schnell

		l0 0.17 <
		{if}
			0 (S.L.cp_wischer_intervall_sw) (S.L.cp_wischer_einaus_sw) (S.L.cp_wischer_schnell_sw)
			0 (S.L.cockpit_wischer_drehschalter_mode)		
		{else} 
			l0 0.5 <
			{if}
				1 (S.L.cp_wischer_intervall_sw) (S.L.cockpit_wischer_drehschalter_mode)
				0 (S.L.cp_wischer_schnell_sw) (S.L.cp_wischer_einaus_sw)
			{else}
				l0 0.83 <
				{if}
					2 (S.L.cockpit_wischer_drehschalter_mode)
					1 (S.L.cp_wischer_einaus_sw)
					0 (S.L.cp_wischer_intervall_sw) (S.L.cp_wischer_schnell_sw)
				{else}
					3 (S.L.cockpit_wischer_drehschalter_mode)
					1 (S.L.cp_wischer_einaus_sw) (S.L.cp_wischer_schnell_sw)
					0 (S.L.cp_wischer_intervall_sw)
				{endif}
			{endif}
		{endif}
'	{endif}

{end}

{trigger:cp_wiper_turnswitch_off}

'	Einrasten auf den festen Positionen:
	(L.L.cockpit_wischer_drehschalter_mode) 3 / (S.L.cockpit_wischer_drehschalter)
{end}

{macro:blinkerhebel_frame}
	(L.L.lights_sw_blinker) 1 =
	{if}	
		-1 (S.L.cockpit_blinkerhebel)
	{else}
		(L.L.lights_sw_blinker) 2 =
		{if}
			1 (S.L.cockpit_blinkerhebel)
		{else}
			0 (S.L.cockpit_blinkerhebel)
		{endif}
	{endif}

'	Hebel-Animation f�r Fernlicht
	(L.L.lights_sw_fern)
	{if}	
		(L.L.cockpit_fernlichthebel) -1 = !
		{if}
			1 (S.L.cockpit_fernlichthebel)
		{endif}

		(L.L.cp_schluessel_rot) 0.8 >
		{if}
			-1 (S.L.cockpit_fernlichthebel)
		{endif}
	{else}
		0 (S.L.cockpit_fernlichthebel)
	{endif}
{end}

{trigger:cp_fold1_drag}
	(L.S.mouse_y) 250 / (L.L.cp_fold1_pos) + (S.L.cp_fold1_pos) s0
	l0 0 <
	{if}
		0 (S.L.cp_fold1_pos)
	{endif}
	l0 1 >
	{if}
		1 (S.L.cp_fold1_pos)
	{endif}

{end}

{trigger:cp_fold1_off}
	0 (S.L.cp_fold1_pos)
{end}

{trigger:cp_fold2_drag}
	(L.S.mouse_y) 250 / (L.L.cp_fold2_pos) + (S.L.cp_fold2_pos) s0
	l0 0 <
	{if}
		0 (S.L.cp_fold2_pos)
	{endif}
	l0 1 >
	{if}
		1 (S.L.cp_fold2_pos)
	{endif}

{end}

{trigger:cp_fold2_off}
	0 (S.L.cp_fold2_pos)
{end}

{trigger:cp_fold3_drag}
	(L.S.mouse_y) 250 / (L.L.cp_fold3_pos) + (S.L.cp_fold3_pos) s0
	l0 0 <
	{if}
		0 (S.L.cp_fold3_pos)
	{endif}
	l0 1 >
	{if}
		1 (S.L.cp_fold3_pos)
	{endif}

{end}

{trigger:cp_fold3_off}
	0 (S.L.cp_fold3_pos)
{end}

{trigger:cp_fold4_drag}
	(L.S.mouse_y) 250 / (L.L.cp_fold4_pos) + (S.L.cp_fold4_pos) s0
	l0 0 <
	{if}
		0 (S.L.cp_fold4_pos)
	{endif}
	l0 1 >
	{if}
		1 (S.L.cp_fold4_pos)
	{endif}

{end}

{trigger:cp_fold4_off}
	0 (S.L.cp_fold4_pos)
{end}

' Spheros Hatch Control
'

{macro:Spheros_frame}
	(L.L.elec_busbar_main)
	{if}
		(L.L.lights_start_done) 1 =
		{if}
			(L.L.cp_spheros_selected) 0 =
			{if}
				1 (S.L.cp_spheros_0_sel_light)
				0 (S.L.cp_spheros_1_sel_light)
			{else}
				0 (S.L.cp_spheros_0_sel_light)
				1 (S.L.cp_spheros_1_sel_light)
			{endif}

			(L.L.cp_spheros_0_up_act)
			{if}
				(L.L.cp_spheros_0_up) 1 <
				(L.L.elec_busbar_main) &&
				{if}
					(L.L.cp_spheros_0_up) 2 (L.S.Timegap) * + (S.L.cp_spheros_0_up)
				{endif}
				1 (S.L.cp_spheros_0_up_light)
			{else}
				(L.L.cp_spheros_0_up) 0 >
				(L.L.elec_busbar_main) &&
				{if}
					(L.L.cp_spheros_0_up) 2 (L.S.Timegap) * - (S.L.cp_spheros_0_up)
				{endif}
				0 (S.L.cp_spheros_0_up_light)
			{endif}

			(L.L.cp_spheros_0_down_act)
			{if}
				(L.L.cp_spheros_0_down) 1 <
				(L.L.elec_busbar_main) &&
				{if}
					(L.L.cp_spheros_0_down) 2 (L.S.Timegap) * + (S.L.cp_spheros_0_down)
				{endif}
				1 (S.L.cp_spheros_0_down_light)
			{else}
				(L.L.cp_spheros_0_down) 0 >
				(L.L.elec_busbar_main) &&
				{if}
					(L.L.cp_spheros_0_down) 2 (L.S.Timegap) * - (S.L.cp_spheros_0_down)
				{endif}
				0 (S.L.cp_spheros_0_down_light)
			{endif}

			(L.L.cp_spheros_1_up_act)
			{if}
				(L.L.cp_spheros_1_up) 1 <
				(L.L.elec_busbar_main) &&
				{if}
					(L.L.cp_spheros_1_up) 2 (L.S.Timegap) * + (S.L.cp_spheros_1_up)
				{endif}
				1 (S.L.cp_spheros_1_up_light)
			{else}
				(L.L.cp_spheros_1_up) 0 >
				(L.L.elec_busbar_main) &&
				{if}
					(L.L.cp_spheros_1_up) 2 (L.S.Timegap) * - (S.L.cp_spheros_1_up)
				{endif}
				0 (S.L.cp_spheros_1_up_light)
			{endif}

			(L.L.cp_spheros_1_down_act)
			{if}
				(L.L.cp_spheros_1_down) 1 <
				(L.L.elec_busbar_main) &&
				{if}
					(L.L.cp_spheros_1_down) 2 (L.S.Timegap) * + (S.L.cp_spheros_1_down)
				{endif}
				1 (S.L.cp_spheros_1_down_light)
			{else}
				(L.L.cp_spheros_1_down) 0 >
				(L.L.elec_busbar_main) &&
				{if}
					(L.L.cp_spheros_1_down) 2 (L.S.Timegap) * - (S.L.cp_spheros_1_down)
				{endif}
				0 (S.L.cp_spheros_1_down_light)
			{endif}

		{else}
			0 (S.L.cp_spheros_0_sel_light) (S.L.cp_spheros_0_up_light) (S.L.cp_spheros_0_down_light) (S.L.cp_spheros_1_sel_light) (S.L.cp_spheros_1_up_light) (S.L.cp_spheros_1_down_light)
		{endif}
	{else}
		0 (S.L.cp_spheros_0_sel_light) (S.L.cp_spheros_0_up_light) (S.L.cp_spheros_0_down_light) (S.L.cp_spheros_1_sel_light) (S.L.cp_spheros_1_up_light) (S.L.cp_spheros_1_down_light)
	{endif}
{end}

{trigger:spheros_select}
	1 (S.L.cp_spheros_select_sw)
	(L.L.elec_busbar_main)
	{if}
		(L.L.cp_spheros_selected) 0 =
		{if}
			1 (S.L.cp_spheros_selected)
		{else}
			0 (S.L.cp_spheros_selected)
		{endif}
	{endif}
{end}

{trigger:spheros_select_off}
	0 (S.L.cp_spheros_select_sw)
{end}

{trigger:spheros_up}
	1 (S.L.cp_spheros_up_sw)
	(L.L.elec_busbar_main)
	{if}
		(L.L.cp_spheros_selected) 0 =
		{if}
			1 (S.L.cp_spheros_0_up_act)
		{else}
			1 (S.L.cp_spheros_1_up_act)
		{endif}
	{endif}
{end}

{trigger:spheros_up_off}
	0 (S.L.cp_spheros_up_sw)
{end}

{trigger:spheros_down}
	1 (S.L.cp_spheros_down_sw)
	(L.L.elec_busbar_main)
	{if}
		(L.L.cp_spheros_selected) 0 =
		{if}
			1 (S.L.cp_spheros_0_down_act)
		{else}
			1 (S.L.cp_spheros_1_down_act)
		{endif}
	{endif}
{end}

{trigger:spheros_down_off}
	0 (S.L.cp_spheros_down_sw)
{end}

{trigger:spheros_open}
	1 (S.L.cp_spheros_open_sw)
	(L.L.elec_busbar_main)
	{if}
		(L.L.cp_spheros_selected) 0 =
		{if}
			1 (S.L.cp_spheros_0_up_act)
			1 (S.L.cp_spheros_0_down_act)
		{else}
			1 (S.L.cp_spheros_1_up_act)
			1 (S.L.cp_spheros_1_down_act)
		{endif}
	{endif}
{end}

{trigger:spheros_open_off}
	0 (S.L.cp_spheros_open_sw)
{end}

{trigger:spheros_close}
	1 (S.L.cp_spheros_close_sw)
	(L.L.elec_busbar_main)
	{if}
		(L.L.cp_spheros_selected) 0 =
		{if}
			0 (S.L.cp_spheros_0_up_act)
			0 (S.L.cp_spheros_0_down_act)
		{else}
			0 (S.L.cp_spheros_1_up_act)
			0 (S.L.cp_spheros_1_down_act)
		{endif}
	{endif}
{end}

{trigger:spheros_close_off}
	0 (S.L.cp_spheros_close_sw)
{end}

' End
'