Scripttexturen mit mehreren Variablen (Dash)

' vdv_kneel_display(_target) states:
' 0 = Knelt up
' 1 = Kneeling in progress (blinking in sync with door clearance)
' 2 = Completely knelt down (displayed constantly)
(L.L.kneel_upsound) (L.L.kneel_downsound) ||
{if}
    (L.L.vdv_blink) !
{else}
'   Strictly-less (<) means that the normal / automatic kneeling won't trigger
'   the new behavior, since it stops at exactly -0.03; if that's undesired,
'   change to less-than-or-equal-to (<=).
    (L.L.kneel_setpoint) -0.03 < 2 *
{endif}
(S.L.vdv_kneel_display_target) (L.L.vdv_kneel_display) = !
{if}
    1 (S.L.vdv_refresh)
{endif}

{macro:vdv_kneel_display_refresh}
    (L.L.vdv_kneel_display_target) s0 0 =
    {if}
        (M.L.vdv_kneel_display_clear)
    {else}
        l0 1 =
        {if}
            (M.L.vdv_kneel_display_active)
        {else}
            (M.L.vdv_kneel_display_forced_down)
        {endif}
    {endif}

    l0 (S.L.vdv_kneel_display)
{end}

{macro:vdv_kneel_display_active}
    (M.L.vdv_kneel_display_clear)
    0 s2 "^" (M.L.vdv_kneel_display_output)
{end}

{macro:vdv_kneel_display_forced_down}
    (M.L.vdv_kneel_display_clear)
'   '_' is 16 pixels wide, so 6 pixels wider than '^' (10 pixels wide), so for
'   seamless transitions the starting x-coordinate needs to be shifted to the
'   left by half of said width difference, i.e. by 3 pixels.
'   Note: Since this patch is only dealing with 2 cases of single-character
'   strings, I'm opting to hard-code their widths instead of relying on the
'   TextLength system-macro, in the hopes of a slight performance advantage.
    3 s2 "_" (M.L.vdv_kneel_display_output)
{end}

{macro:vdv_kneel_display_clear}
'   Optimization: Don't clear again if the last recorded action also was to
'   clear (or when nothing has been output to begin with).
'   Note that the other two cases (~active, ~forced_down) must unfortunately
'   be repeated with each frame, as other portions of vdv_frame can otherwise
'   (partially) overwrite the formers' output, because of their own imprecise
'   clearing logic, and therefore the desired kneeling symbol has to be
'   perpetually re-submitted for rendering even when unchanged in principle.
'   In an ideal world, the top-level macro (and, if necessary, the font) would
'   be refactored such that no two STTextOut calls are at risk of
'   (inadvertently) addressing the same or overlapping coordinates of the same
'   texture. This would reduce the frequency of script-texture updates, for the
'   further benefit of performance. 

    (L.L.vdv_kneel_display) s2
    {if}
        l2 1 =
        {if}
'           '^' char was output the last time around
'           - zero x-offset needed
            0 s2
'           - 10 pixels to be overwritten
            10
        {else}
'           '_' char was output the last time around
'           - x-offset of -3 pixels
            3 s2
'           - 16 pixels to be overwritten
            16
        {endif}
        "|" $* (M.L.vdv_kneel_display_output)
    {endif}
{end}

{macro:vdv_kneel_display_output}
' string-stack 0 : output string
    (S.$.vdv_kneel_display_str)

' l2 : x-offset
    41 l2 - s3 (M.L.vdv_kneel_display_output_0)
    101 l2 - s3 (M.L.vdv_kneel_display_output_0)
    115 l2 - s3 (M.L.vdv_kneel_display_output_0)
{end}

{macro:vdv_kneel_display_output_0}
'   l1 : font
'   l3 : starting x-coordinate
    1
    l3
    47
    l1
    0
    0
    (L.$.vdv_kneel_display_str)
    (M.V.STTextOut)
{end}