= Englisch [EN], 
= Deutsch [DE], 
= Französisch [FR]. Wenn du die angegebene Sprache nicht beherrschst, schreibe auf Englisch! 
Hä? Also das verstehe ich nicht...
Du willst 'nen Bus auswählen, der Tank soll dann immer zu 20% voll sein und plötzlich auf 100% aufsteigen?? Also anders gesagt: den neuen Bus immer mit 100% Tankinhalt spawnen oder was?
Hä? Also das verstehe ich nicht...
Du willst 'nen Bus auswählen, der Tank soll dann immer zu 20% voll sein und plötzlich auf 100% aufsteigen?? Also anders gesagt: den neuen Bus immer mit 100% Tankinhalt spawnen oder was?
Nein. So wie ich das verstehe meint er, dass der Bus beim sparnen 20% hat und er dann Tanken muss, bevor er seine Fahrt antritt.
Na dann...
{macro:engine_init}
50 200 random + (S.L.engine_tank_content)
50 200 random + (S.L.engine_adblue_content)
(L.S.Weather_Temperature) (S.L.engine_temperature) (S.L.engine_temperature_envir)
(C.L.engine_RPM_ign_cold) (S.L.engine_RPM_ign)
{end}Und den Wert vor engine_tank_content auf 40 abändern... Dann müsste es eigentlich klappen.
Also am Ende muss dann 40 (S.L.engine_tank_content) dastehen...
Hallo,
vielen Dank. Ich wollte dies mit dem E Bus aus Hamburg ausprobieren, aber ich weiß nicht genau an welcher stelle.
Ich habe hier mal die ganze Datei:
'##############
'Engine Script
'##############
' 2020 Hamburg electric bus by Darius Bode
'------------------------------------------------------------------------------------------
'----------------------
' Trigger
'----------------------
{trigger:veh_tank}
(C.L.oil_tank_capac) (S.L.oil_tank_content)
(L.L.electric_klappe) (L.L.engine_on) ! &&
{if}
1 (S.L.electric_cable_vis)
{endif}
{end}
{trigger:electric_klappe_toggle}
(L.L.electric_cable_vis) !
{if}
(L.L.electric_klappe) ! (S.L.electric_klappe)
{endif}
{end}
{trigger:electric_cable_toggle}
0 (S.L.electric_cable_vis)
{end}
'----------------------
' Init
'----------------------
{macro:engine_init}
(C.L.oil_tank_capac) 2 / (C.L.oil_tank_capac) 2 / random + (C.L.oil_tank_capac) min (S.L.oil_tank_content)
3 (S.L.engine_ignition)
(L.S.Weather_Temperature) (S.L.battery_temperature)
(C.L.electric_battery_capacity) 1.5 / (C.L.electric_battery_capacity) random + (S.L.electric_battery)
{end}
'----------------------
' Frame
'----------------------
{macro:engine_frame}
(L.L.AI) !
{if}
(M.L.servo)
{endif}
(M.L.battery_temperature)
(M.L.electric)
(L.L.electric_cable_vis)
{if}
(M.L.electric_charge)
{endif}
' Sound E-Antrieb
(L.L.electric_E_M) 0.01 > (L.L.antrieb_retardermoment) -100 < ||
(L.L.Throttle) 0.01 > (L.L.Brake) 0.01 > || ||
(L.L.electric_main) &&
(S.L.electric_sound_summen)
(L.L.electric_E_M) (L.L.antrieb_retardermoment) 1000 / +
-1 max 1 min (S.L.electric_sound_last)
(L.L.Velocity) (F.L.electric_sound_pitch) (S.L.electric_sound_pitch)
(L.L.Velocity) (F.L.achse_sound_pitch) (S.L.achse_sound_pitch)
' Ignition control (0 running, 1 start, 2 shut down, 3 off)
' ##################################################################
' START
' ##################################################################
(L.L.engine_ignition) 1 = (L.L.elec_busbar_main) && (L.L.electric_cable_vis) ! && (L.L.electric_battery) 0.01 >= &&
{if}
(L.L.engine_startwait) (L.S.Timegap) + (S.L.engine_startwait) s0
l0 (C.L.engine_startdelay) >
{if}
(L.L.engine_ignitiontime) 0 =
{if}
(L.L.globaltimer) (S.L.engine_ignitiontime)
{endif}
(L.L.globaltimer) (L.L.engine_ignitiontime) (L.S.Timegap) + >
{if}
(L.L.engine_on) !
{if}
(T.L.ev_eng_ignited)
(M.L.failure_random)
{endif}
(L.L.globaltimer) (S.L.engine_starttime)
1 (S.L.engine_on)
3 (S.L.electric_power_level)
0 (S.L.engine_ignition)
{else}
(L.L.engine_on) !
{if}
(T.L.ev_eng_start)
{endif}
{endif}
{endif}
{else}
0 (S.L.engine_startwait)
{endif}
' ##################################################################
' SHUT DOWN
' ##################################################################
(L.L.engine_ignition) 2 = (L.L.cp_notaus_hochvolt) (L.L.engine_ignition) 0 = && || (L.L.cp_killsw_batterie) (L.L.engine_ignition) 0 = && ||
{if}
2 (S.L.engine_ignition)
(L.L.engine_stopwait) (L.S.Timegap) + (S.L.engine_stopwait) s0
l0 (C.L.engine_stopdelay) >
{if}
1 (S.L.bremse_ABS_selftest)
(L.L.globaltimer) (S.L.cockpit_engineshutdowntime)
3 (S.L.engine_ignition)
0 (S.L.engine_stopwait) (S.L.engine_on) (S.L.vdv_display_rot_wennstop)
0 (S.L.electric_power_level)
{endif}
{else}
0 (S.L.engine_stopwait)
{endif}
' Geschwindigkeitsbegrenzer und E-Gas
(L.L.engine_on) ! (L.L.bremse_halte) (L.L.bremse_anfahrsperre) || ||
{if}
0 (S.L.engine_internal_throttle)
{else}
(L.L.cp_notloese_EMR) ! (L.L.antrieb_EMR_failure) ! &&
{if}
(L.L.throttle) (F.L.throttle_hyst) s0
l0 (L.L.Velocity) (F.L.egb_vmax) * s0
l0 (S.L.engine_internal_throttle)
{endif}
{endif}
' Motormanagement durch ASR-Eingriff, sofern vorhanden
(L.L.engine_on)
{if}
(L.L.Wheel_RotationSpeed_1_L) (L.L.Wheel_RotationSpeed_1_R) + 2 / abs (L.L.Wheel_RotationSpeed_0_L) (L.L.Wheel_RotationSpeed_0_R) + 2 / 10 + abs >
(L.L.Wheel_RotationSpeed_1_L) 1 > &&
(L.L.Wheel_RotationSpeed_1_R) 1 > &&
(L.L.engine_internal_throttle) 0 > &&
{if}
(L.L.engine_ASR_eingriff) !
{if}
(T.L.ev_bremse_ABS_on)
{endif}
1 (S.L.engine_ASR_eingriff)
{endif}
(L.L.Wheel_RotationSpeed_1_L) (L.L.Wheel_RotationSpeed_1_R) + 2 / abs (L.L.Wheel_RotationSpeed_0_L) (L.L.Wheel_RotationSpeed_0_R) + 2 / 8 + abs <
{if}
(L.L.engine_ASR_eingriff)
{if}
(T.L.ev_bremse_ABS_off)
{endif}
0 (S.L.engine_ASR_eingriff)
{endif}
(L.L.engine_ASR_eingriff)
{if}
0 (S.L.engine_internal_throttle)
{endif}
(L.L.cp_asroffsw_targeton) (L.L.Velocity) 15 < &&
{if}
0 (S.L.engine_ASR_eingriff)
{endif}
{endif}
' Stoerungen
' Anzeige Ueberdrehzahl:
(L.L.Velocity) 95 >
(L.L.antrieb_getr_aktugang) 1 > &&
{if}
1 (S.L.electric_fail_drehzahl)
{endif}
(L.L.Velocity) 85 <
(L.L.antrieb_getr_aktugang) 1 <= ||
{if}
0 (S.L.electric_fail_drehzahl)
{endif}
(L.L.elec_busbar_main_sw) !
{if}
0 (S.L.electric_fail_busbar)
(S.L.electric_fail_widerstand)
(S.L.electric_fail_redundanz)
(S.L.electric_fail_bordnetz)
(S.L.electric_fail_antrieb)
(S.L.niveau_fehler_random)
(S.L.c2_display_rot_system_random)
(S.L.c2_display_gelb_kraftstoff_random)
{else}
(L.L.electric_fail_busbar) !
{if}
(M.L.failure_random)
1 (S.L.electric_fail_busbar)
{endif}
{endif}
' Debug
(L.L.elec_busbar_main) !
(L.L.electric_battery) 0.01 < ||
{if}
0 (S.L.engine_on) (S.L.electric_main)
3 (S.L.engine_ignition)
{endif}
{end}
{macro:battery_temperature}
' Unterschied Batterietemperatur/Aussentemperatur
(L.L.battery_temperature) (L.S.Weather_Temperature) - /-/ (S.L.battery_rate_envir)
' Batterieheizung
(L.L.elec_busbar_main)
{if}
' Einschaltschwelle Batterieheizung
(L.L.battery_temperature) (C.L.battery_ideal_temp) 5 - <
{if}
(L.L.zusatzheizung_switched) (L.L.coolant_temperature) (L.L.battery_temperature) > ||
(L.L.coolant_temperature) 20 > &&
{if}
(L.L.battery_temperature) (L.L.coolant_temperature) - /-/ (S.L.battery_rate_aux)
0 (S.L.battery_heat_elec)
{else}
(L.L.electric_battery) (F.L.electric_load_eff) (S.L.battery_heat_elec)
0 (S.L.battery_rate_aux)
{endif}
0 (S.L.battery_vents)
{else}
' Abschaltschwelle Batterieheizung
(L.L.battery_temperature) (C.L.battery_ideal_temp) 5 + >
{if}
0 (S.L.battery_rate_aux) (S.L.battery_heat_elec)
{endif}
' Einschaltschwelle Batteriekuehlung
(L.L.battery_temperature) (C.L.battery_ideal_temp) 15 + >
{if}
1 (S.L.battery_vents)
{endif}
{endif}
{else}
0 (S.L.battery_heat_elec) (S.L.battery_rate_aux) (S.L.battery_vents)
{endif}
' Summe Batterietemp
(L.L.battery_rate_envir) 5000 / (L.S.Timegap) *
(L.L.battery_rate_aux) 1300 / (L.S.Timegap) * +
(L.L.battery_heat_elec) (C.L.battery_heat_eff) * (L.S.Timegap) * +
(L.L.battery_vents) (C.L.battery_vent_eff) * (L.S.Timegap) * -
(L.L.battery_temperature) +
(S.L.battery_temperature)
{end}
' ////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
' ////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
' HOCHVOLT-STEUERUNG
' ////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
{macro:electric}
' (L.L.electric_battery) (L.L.Clutch) (L.S.Timegap) * + (S.L.electric_battery)
' System Hauptschaltung
(L.L.engine_on)
(L.L.electric_battery) 0.01 >= &&
(L.L.cp_notaus_hochvolt) ! &&
(L.L.elec_busbar_main_sw) &&
{if}
(L.L.electric_main) !
{if}
(L.L.electric_main_timer) (L.S.Timegap) + (S.L.electric_main_timer)
1 >
{if}
1 (S.L.electric_main)
0 (S.L.electric_main_timer)
{endif}
{endif}
{else}
(L.L.electric_battery) 0.01 <
(L.L.elec_busbar_main) ! ||
(L.L.engine_on) ! ||
{if}
0 (S.L.electric_main) (S.L.electric_main_timer)
{endif}
{endif}
' Power-Level
(L.L.electric_battery) (C.L.electric_battery_capacity) / s0
l0 0.1 >=
(L.L.c2_display_rot_antrieb) ! &&
{if}
3 (S.L.electric_power_level)
{endif}
l0 0.1 < l0 0.05 > &&
(L.L.c2_display_rot_antrieb) l0 0.1 >= && ||
{if}
2 (S.L.electric_power_level)
{endif}
l0 0.01 > l0 0.05 <= &&
{if}
1 (S.L.electric_power_level)
{endif}
l0 0.01 <=
{if}
0 (S.L.electric_power_level)
{endif}
' Hochvoltbatterie
(L.L.electric_battery)
' Verbraucher
(L.L.c2klima_fahrergeblaese) 9000 / -
(L.L.kopflueftung) 14000 / -
(L.L.fahrgastklima_sound) 8000 / -
(L.L.bremse_kompressor) 8000 / (L.L.engine_on) * -
(L.L.battery_heat_elec) 800 / -
(L.L.battery_vents) 6000 / -
(L.L.elec_V_generator) 8000 / -
' Antriebsleistung
(L.L.electric_E_M) (L.L.engine_on) (L.L.AI) 2 / - * 600 / -
' Laden durch Rekuperation
(L.L.antrieb_retardermoment) abs 100000 / 12 / (C.L.electric_load_by_recup) * +
0 max (C.L.electric_battery_capacity) min
(S.L.electric_battery)
' E-Motor
(L.L.electric_main) (L.L.antrieb_getr_aktugang) 1 = ! &&
(L.L.engine_on) &&
{if}
(L.L.engine_internal_throttle)
(L.L.Velocity) (F.L.egb_vmax) *
(L.L.Velocity) (F.L.electric_eff_vel) *
(L.L.electric_battery) (F.L.electric_load_eff) *
(L.L.battery_temperature) (F.L.electric_temp_eff) *
(L.L.electric_power_level) 3 / *
(L.L.engine_no_throttle) -
(L.L.bremse_halte) -
(L.L.bremse_anfahrsperre) -
s0
(L.L.electric_E_M) s1
0.8 s2
4 s3
(M.L.engine_traegheit)
0 max (S.L.electric_E_M)
{else}
0 (S.L.electric_E_M)
{endif}
' Wenn Antrieb aus, Rücksetzung der Zähler
(L.L.engine_on) !
(L.L.engine_ignition) 3 = &&
{if}
0 (S.L.engine_ignitiontime) (S.L.engine_starttime)
{endif}
' String der Batterieladeanzeige (var gehoert zum Cockpit)
(L.L.electric_battery) (C.L.electric_battery_capacity) / 100 * 0.1 + $IntToStr (S.$.electric_battery_string)
{end}
{macro:servo}
(L.L.electric_main)
{if}
(L.L.Axle_Steering_0_L) abs (C.L.servo_steer_1) >
(L.L.Velocity) (C.L.servo_vel) > ||
{if}
1 (F.L.servo_output) (S.L.servo_output_target)
(L.L.Axle_Steering_0_L) abs (C.L.servo_steer_2) >
{if}
2 (F.L.servo_output) (S.L.servo_output_target)
(L.L.Axle_Steering_0_L) abs (C.L.servo_steer_3) >
{if}
3 (F.L.servo_output) (S.L.servo_output_target)
{endif}
{endif}
{else}
0 (S.L.servo_output_target)
{endif}
{else}
0 (S.L.servo_output_target)
{endif}
(L.L.servo_output_target) (L.L.servo_output) = !
{if}
(L.L.servo_stoptime) 0 =
{if}
(L.L.globaltimer) (C.L.servo_stop_delay) + (S.L.servo_stoptime)
{endif}
(L.L.servo_output) 0 >
(L.L.servo_running) ! &&
{if}
1 (S.L.servo_running)
(T.L.ev_servo_start)
{endif}
(L.L.servo_output) 0 <=
(L.L.servo_running) &&
{if}
0 (S.L.servo_running) (S.L.servo_stoptime)
(T.L.ev_servo_stop)
{endif}
(L.L.servo_output) (L.L.servo_output_target) <
{if}
0 (S.L.servo_stoptime)
(L.L.servo_output) (L.S.Timegap) (C.L.servo_speed) * + (L.L.servo_output_target) min (S.L.servo_output)
{endif}
(L.L.servo_output) (L.L.servo_output_target) >
(L.L.globaltimer) (L.L.servo_stoptime) >= &&
{if}
(L.L.servo_output) (L.S.Timegap) (C.L.servo_speed) * - (L.L.servo_output_target) max (S.L.servo_output)
{endif}
{else}
0 (S.L.servo_stoptime)
{endif}
(L.L.servo_output) (F.L.servo_output_pitch) (S.L.servo_output_pitch)
{end}
{macro:electric_charge}
1 (S.L.electric_cable_vis)
(L.L.engine_on) !
{if}
(L.L.electric_battery) (C.L.electric_charge_speed) 10 / (L.S.Timegap) * + (C.L.electric_battery_capacity) min (S.L.electric_battery)
{endif}
{end}
{macro:engine_traegheit}
'Simuliert träges Verhalten (exponentiell)
'Ladekonventionen:
' Sollwert l0
' Istwert l1
' Konstante Anlauf l2 (Einheiten/s)
' Konstante Ablauf l3 (Einheiten/s)
'Anlauf oder Auslauf?
l0 l1 >
{if}
l2 (L.S.Timegap) * 1 min -1 max s4
{else}
l3 (L.S.Timegap) * 1 min -1 max s4
{endif}
'Sollwert:
l0
'Istwert:
l1
'Beschleunigung:
- l4 *
'Addition zum Istwert:
l1 + s1
{end}
{macro:failure_random}
' Eine von 7 Zufallsstörungen auswählen. Bei Ergebnis 0 und 8-20 wird keine Störung ausgewählt.
0 20 random s0
(L.L.globaltimer) (M.V.NrSpecRandom) s1
l0 1 = {if}
(L.L.Axle_Steering_0_L) abs 0.2 >
l1 0.5 < &&
{if}
1 (S.L.electric_fail_redundanz)
{endif}
{endif}
l0 2 = {if}
l1 0.5 >
{if}
1 (S.L.c2_display_rot_system_random)
{endif}
{endif}
l0 3 = {if}
(L.L.battery_temperature) 25 >
l1 0.5 < &&
{if}
1 (S.L.electric_fail_bordnetz)
{endif}
{endif}
l0 4 = {if}
(L.L.battery_temperature) 25 >
l1 0.5 > &&
{if}
1 (S.L.electric_fail_antrieb)
{endif}
{endif}
l0 5 = {if}
(L.L.electric_battery) (C.L.electric_battery_capacity) 2 / >
l1 0.5 > &&
{if}
1 (S.L.electric_fail_widerstand)
{endif}
{endif}
l0 6 = {if}
l1 0.5 <
{if}
1 (S.L.niveau_fehler_random)
{endif}
{endif}
l0 7 = {if}
l1 0.5 <
(L.L.Brake) 0.05 > &&
(L.S.Day) 2 % 0.5 > &&
{if}
1 (S.L.c2_display_gelb_kraftstoff_random)
{endif}
{endif}
{end}Du weißt schon warum das Ding E-Bus heißt, oder? 
Da gibt es keinen Tank, nur den Akku.
Und ich sage mal so, 'nen Bus aufladen dauert wesentlich länger, als nur vollzutanken.
Letzten Endes wird das über die untere Zeile geregelt:
(C.L.electric_battery_capacity) 1.5 / (L.L.electric_battery_capacity) random + (S.L.eletric_battery)
Es wird der Wert von "electric_battery_capacity" aus der Constfile genommen. Dieser wird durch 1,5 gerechnet.
Dann wird nochmal der Wert "electric_battery_capacity" genommen. Von beiden Ergebnissen wird nun eine zufällige Ziffer (random) ausgesucht.
5 100 random bedeutet z.B., dass eine zufällige Zahl von 5 bis 100 genommen wird.
Und am Ende wird das Ergebnis auf "eletric_battery" gespeichert.
Das heißt du musst die untere Zeile einfach durch <beliebiger Wert> (S.L.eletric_battery) ersetzen.
Was da allerdings für ne Zahl rauskommt, keine Ahnung. Musst die o.g. Rechnung einmal selber durchrechnen...
EDIT: Wobei ich noch nicht einmal weiß, ob man die E-Busse in OMSI (insbesondere den eCitaro) selber aufladen kann?! Der Tankinhalt steht nämlich dauerhaft auf 0%. Und an die Tanke kannste damit nicht fahren. Da wird mMn nix aufgeladen.
Danke. !
Ja auf dem Betriebshof Alsterdorf kann man den Bus laden.