= Englisch [EN], 
= Deutsch [DE], 
= Französisch [FR]. Wenn du die angegebene Sprache nicht beherrschst, schreibe auf Englisch! Hallo,
ich habe heute versucht die Lichtautomatik und das Abbiegelicht aus dem C2E in den C2 LE (Hochbahn Ausführung) einzubauen. Modell und Texturen wurden bereits durch mich angepasst. Auch die Scripte wurden bereits übernommen und entsprechend angepasst. Der Bus funktioniert auch soweit ohne Probleme. Nur die Lichtautomatik funktioniert nicht. Wenn ich den Schalter auf A schalte und den Bus dann Nachts anlasse, passiert nichts. Es geht lediglich das TFL an, als wäre der Schalter auf 0. Außerdem wird das A am Lichtschalter nicht beleuchtet, sobald ich das Licht manuell einschalte. Ich habe mittlerweile sämtliche Scripte durchforstet, allerdings nichts gefunden was noch mit der Lichtautomatik in Verbindung stehen könnte. Allmählich habe ich echt keinen Plan mehr was da noch fehlen könnte. Die Logfile zeigt sich da dann auch komplett ahnungslos. Kein Fehler in der Beleuchtung, Elektrik oder sonstigem.
Ich hänge mal die Skriptdateien die ich verändert habe in Ausschnitten an sowie die Logfile. Vielleicht kann mir ja jemand von euch helfen. 
Code: lights.osc
'##############
'LightScript
'##############
'Simulates lighting system
'(c) 11.05.2009 Rüdiger Hülsmann
'(c) 02.01.2011 Marcel Kuhnt
' modified for Hamburg addon Darius Bode 2012
' modified for Gelenkbus Darius Bode 2013
'Script Version: 1.1
'Omsi release: 1.0
'Needs:
'- Cockpit (Batterietrennschalter)
'- Door (Haltestellenbremse für Bremslicht)
'Revision History:
'- Rüdiger Hülsmann 11.05.2009 Bremslichter an Bremsdruck gekoppelt
'- Marcel Kuhnt 10.06.2009 Schlüsselschalter-Logik für Stand- und Abbl.-licht verändert, Fernlicht hinzugefügt
'- Marcel Kuhnt 10.08.2009 Added Revision History
'- Marcel Kuhnt & RÜH 22.10.2009 Removed Light Switch Sound (added to cockpit)
'- Rüdiger Hülsmann 28.10.2009 Added changeover variable for lower level and front right interior light (fixed light overlay problem)
'- Rüdiger Hülsmann 18.07.2010 Light switch adapted to new ignition key algorithm
'- Marcel Kuhnt 21.09.2010 Changed interpretation of AI_Light, light flasher
'- RÜdiger Hülsmann 15.11.2010 AI-warning lights
'- Rüdiger Hülsmann 21.11.2010 Interiour and warning lights independent from busbar_main, blinker fix (situation reload)
'- Rüdiger Hülsmann 27.11.2010 Warning lights bug removed
'- Rüdiger Hülsmann 08.12.2010 Light bug "untenohnevornerechts" removed
'- Marcel Kuhnt 28.12.2010 Extracted AI lighting in separated macro (for using with AI script)
'- Marcel Kuhnt 02.01.2011 Corrected AI warn blinker deactivation
'- Rüdiger Hülsmann 02.01.2011 Driver light fixed
'- Rüdiger Hülsmann 05.01.2011 Fog lamp
'- Rüdiger Hülsmann 07.01.2011 highbeam switch sound
'- Rüdiger Hülsmann 18.01.2011 Blinker switch on sound added
'- Darius Bode 05.09.2013 Stromsparschaltung, Test fuer neue Innenbeleuchtung
'------------------------------------------------------------------------------------------
{trigger:kw_fernlicht_toggle}
(L.L.lights_sw_fern) ! (S.L.lights_sw_fern)
{if} (T.L.ev_fernlicht_an) {else} (T.L.ev_fernlicht_aus) {endif}
{end}
{trigger:kw_fernlicht_toggle_off}
(L.L.vdv_lichtschalter_rot_mode)
'Wenn Schlüsselposition Aus oder Standlicht dann Abbl-Licht, dann Fernlicht wieder ausschalten (Lichthupe)
1 <
{if}
0 (S.L.lights_sw_fern)
(T.L.ev_fernlicht_aus)
{endif}
{end}
{trigger:kw_scheinwerfer_toggle}
(L.L.vdv_lichtschalter_rot_mode)
'Wenn Schlüsselposition Aus oder Standlicht dann Abbl-Licht
1 <
{if}
1 (S.L.vdv_lichtschalter_rot_mode)
(T.L.ev_lichtdrehschalter_an)
'Wenn Schlüsselposition Abbl.-Licht dann Aus
{else}
0 (S.L.vdv_lichtschalter_rot_mode)
(T.L.ev_lichtdrehschalter_aus)
0 (S.L.lights_sw_fern)
{endif}
{end}
{trigger:kw_standlicht_toggle}
(L.L.vdv_lichtschalter_rot_mode)
'Wenn Schlüsselposition Aus oder Abbl-Licht dann Standlicht
s0 0.5 > l0 0.5 < ||
{if}
0.5 (S.L.vdv_lichtschalter_rot_mode)
(T.L.ev_lichtdrehschalter_dreh)
'Wenn Schlüsselposition Standlicht dann Aus
{else}
0 (S.L.vdv_lichtschalter_rot_mode)
(T.L.ev_lichtdrehschalter_aus)
0 (S.L.lights_sw_fern)
{endif}
{end}
{trigger:blinker_off}
(L.L.lights_sw_blinker) 0 >
{if}
(T.L.ev_lights_blinker_swoff)
0 (S.L.lights_sw_blinker)
{endif}
{end}
{trigger:blinker_left_move}
(L.L.lights_sw_blinker)
0 =
{if}
1 (S.L.lights_sw_blinker)
(T.L.ev_lights_blinker_swon)
(M.L.lights_startblinkgeber)
{else}
(T.L.ev_lights_blinker_swoff)
0 (S.L.lights_sw_blinker)
{endif}
{end}
{trigger:blinker_right_move}
(L.L.lights_sw_blinker)
0 =
{if}
2 (S.L.lights_sw_blinker)
(T.L.ev_lights_blinker_swon)
(M.L.lights_startblinkgeber)
{else}
(T.L.ev_lights_blinker_swoff)
0 (S.L.lights_sw_blinker)
{endif}
{end}
{trigger:blinker_left_set}
(L.L.lights_sw_blinker) 1 = !
{if}
(T.L.ev_lights_blinker_swon)
{endif}
1 (S.L.lights_sw_blinker)
(M.L.lights_startblinkgeber)
{end}
{trigger:blinker_right_set}
(L.L.lights_sw_blinker) 2 = !
{if}
(T.L.ev_lights_blinker_swon)
{endif}
2 (S.L.lights_sw_blinker)
(M.L.lights_startblinkgeber)
{end}
{trigger:blinker_warn_toggle}
(L.L.lights_sw_warnblinker)
{if}
(L.L.lights_schulbetrieb) !
{if}
0 (S.L.lights_sw_warnblinker)
{endif}
{else}
1 (S.L.lights_sw_warnblinker)
(M.L.lights_startblinkgeber)
{endif}
(L.L.vdv_sw_warnblinker) ! (S.L.vdv_sw_warnblinker)
{if}
(T.L.ev_warnblinker_sw)
{else}
(T.L.ev_warnblinker_sw)
{endif}
{end}
{macro:lights_frame}
' Automatiklicht
(L.L.lights_mode) 3 =
{if}
(L.L.Envir_Brightness) (C.L.lights_auto_on) <
{if}
(L.L.lights_auto_bright_timer) (L.S.Timegap) + (S.L.lights_auto_bright_timer)
(C.L.lights_auto_bright_delay) >
{if}
1 (S.L.lights_auto_req)
0 (S.L.lights_auto_bright_timer)
{endif}
(L.L.engine_n) 3000 230
{if}
2 (S.L.lights_auto_req)
{else}
1 (S.L.lights_auto_req)
{endif}
{else}
(L.L.Envir_Brightness) (C.L.lights_auto_off) >
{if}
(L.L.lights_auto_bright_timer) (L.S.Timegap) + (S.L.lights_auto_bright_timer)
(C.L.lights_auto_bright_delay) >
{if}
0 (S.L.lights_auto_req)
0 (S.L.lights_auto_bright_timer)
{endif}
{endif}
{endif}
(L.L.lights_auto) (L.L.lights_auto_req) = !
{if}
(L.L.lights_auto_timer) (L.S.Timegap) + (S.L.lights_auto_timer)
(C.L.lights_auto_delay) >
{if}
(L.L.lights_auto_req) (S.L.lights_auto)
0 (S.L.lights_auto_timer)
{endif}
{endif}
(L.L.lights_auto) 1 =
{if}
(L.L.elec_busbar_main) (S.L.lights_stand) (S.L.lights_tagfahr)
0 (S.L.lights_abbl)
{else}
(L.L.lights_auto) 2 =
{if}
(L.L.elec_busbar_main) (S.L.lights_abbl) (S.L.lights_stand) (S.L.lights_tagfahr)
{else}
0 (S.L.lights_stand) (S.L.lights_abbl) (S.L.lights_tagfahr)
{endif}
{endif}
{else}
0 (S.L.lights_auto_req) (S.L.lights_auto) (S.L.lights_auto_timer) (S.L.lights_auto_bright_timer)
{endif}
' Rueckfahrlicht
(L.L.elec_busbar_main) (C.L.elec_busbar_Vmin) > (L.L.antrieb_getr_gangwahl) 1 < && (L.L.elec_failure_general) ! &&
{if}
1 (S.L.lights_rueckfahr)
{else}
0 (S.L.lights_rueckfahr)
{endif}
' Kurvenlicht
(L.L.lights_abbl) (L.L.engine_n) 3000 230 &&
{if}
(L.L.lights_sw_blinker) 1 = (L.L.Velocity) 30 < &&
{if}
1 (S.L.lights_kurve_req)
{else}
(L.L.lights_sw_blinker) 2 = (L.L.Velocity) 30 < &&
{if}
2 (S.L.lights_kurve_req)
{else}
0 (S.L.lights_kurve_req)
{endif}
{endif}
{else}
0 (S.L.lights_kurve_req) (S.L.lights_kurve_timer) (S.L.lights_kurve_act)
{endif}
(L.L.lights_kurve_act) (L.L.lights_kurve_req) = !
{if}
(L.L.lights_kurve_timer) (L.S.Timegap) + (S.L.lights_kurve_timer)
(C.L.lights_kurve_delay) >
{if}
(L.L.lights_kurve_req) (S.L.lights_kurve_act)
0 (S.L.lights_kurve_timer)
{endif}
{endif}
(L.L.lights_kurve_act) 1 = (S.L.lights_kurve_l)
(L.L.lights_kurve_act) 2 = (S.L.lights_kurve_r)
' Tagfahrlicht
(L.L.engine_injection_on)
(L.L.lights_stand) ||
(L.L.elec_busbar_avail) &&
(S.L.lights_tagfahr)
' Fuer C2-LED-Rueckleuchten: Gibt an, ob Aus oder eine der Leuchttexturen gebraucht wird
(L.L.lights_rueck) !
(L.L.lights_stand) ! &&
(L.L.lights_brems) ! &&
{if}
1 (S.L.lights_texture_aus)
0 (S.L.lights_texture_brems) (S.L.lights_texture_stand)
{endif}
(L.L.lights_rueck) (L.L.lights_stand) ||
(L.L.lights_brems) ! &&
{if}
0 (S.L.lights_texture_aus) (S.L.lights_texture_brems)
1 (S.L.lights_texture_stand)
{endif}
(L.L.lights_brems)
{if}
1 (S.L.lights_texture_brems)
0 (S.L.lights_texture_aus) (S.L.lights_texture_stand)
{endif}
' Zahltischleuchte
(L.L.elec_busbar_main) (C.L.elec_busbar_Vmin) > (L.L.door_1_aussen_licht) || (L.L.elec_failure_general) ! &&
(L.L.door_0) 0 > (L.L.door_1) 0 > || (L.L.door_1_aussen_licht) || (L.L.lights_stand) && && (L.L.cp_intlightsdriver_targeton) ||
{if}
1 (S.L.lights_fahrerlicht)
{else}
(L.L.cp_intlightsdriver_targeton) ! (L.L.door_1_aussen_licht) ! && (L.L.door_oberlicht1_lichtreq_zeit) 0 = &&
{if}
0 (S.L.lights_fahrerlicht)
{endif}
{endif}
(L.L.elec_busbar_main) (C.L.elec_busbar_Vmin) > (L.L.elec_failure_general) ! &&
{if}
(L.L.cp_saegezahn_licht) (S.L.lights_saegezahn)
{else}
0 (S.L.lights_saegezahn)
{endif}
' Nebelschlussleuchte
(L.L.cp_taster_nebelschluss_target) (L.L.vdv_lichtschalter_rot_mode) 0.2 > (L.L.elec_busbar_main) (C.L.elec_busbar_Vmin) > && && (L.L.elec_failure_general) ! &&
{if}
1 (S.L.lights_nebelschluss)
{else}
0 (S.L.lights_nebelschluss)
{endif}
' Stromsparschaltung Aussenbeleuchtung
(L.L.lights_mode) 2 < (L.L.engine_injection_on) ||
{if}
0 (S.L.lights_stromspar)
{endif}
' Lichtstatus = Drehschalter
(L.L.lights_mode) 0 = (L.L.elec_failure_general) ||
{if}
0 (S.L.lights_stand) (S.L.lights_rueck) (S.L.lights_abbl)
-1 (S.L.Spot_Select)
{endif}
(L.L.lights_mode) 1 =
(L.L.elec_failure_general) ! &&
{if}
1 (S.L.lights_stand) (S.L.lights_rueck)
-1 (S.L.Spot_Select)
0 (S.L.lights_abbl)
{endif}
(L.L.lights_mode) 2 = (L.L.elec_failure_general) ! &&
{if}
(L.L.lights_stromspar) ! (L.L.engine_ignition) 1 = ! && (L.L.elec_busbar_main_sw) &&
{if}
1 (S.L.lights_abbl) (S.L.lights_stand) (S.L.lights_rueck) (S.L.Spot_Select)
{else}
1 (S.L.lights_stand) (S.L.lights_rueck)
-1 (S.L.Spot_Select)
0 (S.L.lights_abbl)
{endif}
{endif}
' Fernlicht
(L.L.lights_sw_fern) (L.L.elec_failure_general) ! &&
{if}
1
(S.L.lights_fern)
(S.L.lights_abbl)
0 (S.L.Spot_Select)
{else}
0 (S.L.lights_fern)
{endif}
' Nebelscheinwerfer
(L.L.cp_nebel_targeton) (L.L.vdv_lichtschalter_rot_mode) 0.2 > (L.L.elec_busbar_main) (C.L.elec_busbar_Vmin) > && && (L.L.elec_failure_general) ! &&
{if}
1 (S.L.lights_nebelscheinw)
{else}
0 (S.L.lights_nebelscheinw)
{endif}
(L.L.cp_nebel_targetoff) (L.L.elec_failure_general) ||
{if}
0 (S.L.lights_nebelscheinw)
{endif}
(M.L.lights_schulbetrieb)
' Tuer-Oberlichter
(L.L.door_0) 0.1 > (L.L.door_1) 0.1 > ||
{if}
1 (S.L.door_oberlicht1_lichtreq)
{else}
(L.L.door_oberlicht1_lichtreq)
{if}
(L.L.door_oberlicht1_lichtreq_zeit) 0 =
{if}
(L.L.globaltimer) (S.L.door_oberlicht1_lichtreq_zeit)
{endif}
(L.L.globaltimer) (L.L.door_oberlicht1_lichtreq_zeit) (C.L.door_licht_verz) + >
{if}
0 (S.L.door_oberlicht1_lichtreq) (S.L.door_oberlicht1_lichtreq_zeit)
{endif}
{endif}
{endif}
(L.L.door_2) 0.1 > (L.L.door_3) 0.1 > ||
{if}
1 (S.L.door_oberlicht2_lichtreq)
{else}
(L.L.door_oberlicht2_lichtreq)
{if}
(L.L.door_oberlicht2_lichtreq_zeit) 0 =
{if}
(L.L.globaltimer) (S.L.door_oberlicht2_lichtreq_zeit)
{endif}
(L.L.globaltimer) (L.L.door_oberlicht2_lichtreq_zeit) (C.L.door_licht_verz) + >
{if}
0 (S.L.door_oberlicht2_lichtreq) (S.L.door_oberlicht2_lichtreq_zeit)
{endif}
{endif}
{endif}
(L.L.door_4) 0.1 > (L.L.door_5) 0.1 > ||
{if}
1 (S.L.door_oberlicht3_lichtreq)
{else}
(L.L.door_oberlicht3_lichtreq)
{if}
(L.L.door_oberlicht3_lichtreq_zeit) 0 =
{if}
(L.L.globaltimer) (S.L.door_oberlicht3_lichtreq_zeit)
{endif}
(L.L.globaltimer) (L.L.door_oberlicht3_lichtreq_zeit) (C.L.door_licht_verz) + >
{if}
0 (S.L.door_oberlicht3_lichtreq) (S.L.door_oberlicht3_lichtreq_zeit)
{endif}
{endif}
{endif}
(L.L.door_6) 0.1 > (L.L.door_7) 0.1 > ||
{if}
1 (S.L.door_oberlicht4_lichtreq)
{else}
(L.L.door_oberlicht4_lichtreq)
{if}
(L.L.door_oberlicht4_lichtreq_zeit) 0 =
{if}
(L.L.globaltimer) (S.L.door_oberlicht4_lichtreq_zeit)
{endif}
(L.L.globaltimer) (L.L.door_oberlicht4_lichtreq_zeit) (C.L.door_licht_verz) + >
{if}
0 (S.L.door_oberlicht4_lichtreq) (S.L.door_oberlicht4_lichtreq_zeit)
{endif}
{endif}
{endif}
(L.L.door_8) 0.1 > (L.L.door_9) 0.1 > ||
{if}
1 (S.L.door_oberlicht5_lichtreq)
{else}
(L.L.door_oberlicht5_lichtreq)
{if}
(L.L.door_oberlicht5_lichtreq_zeit) 0 =
{if}
(L.L.globaltimer) (S.L.door_oberlicht5_lichtreq_zeit)
{endif}
(L.L.globaltimer) (L.L.door_oberlicht5_lichtreq_zeit) (C.L.door_licht_verz) + >
{if}
0 (S.L.door_oberlicht5_lichtreq) (S.L.door_oberlicht5_lichtreq_zeit)
{endif}
{endif}
{endif}
(L.L.door_oberlicht1_lichtreq)
(L.L.elec_busbar_main) && (L.L.lights_stand) && (L.L.elec_failure_general) ! &&
(L.L.door_1_aussen_licht) ||
{if}
1 (S.L.door_oberlicht1)
{else}
0 (S.L.door_oberlicht1)
{endif}
' Innenlicht wenn Tuer von aussen geoeffnet wurde
(L.L.door_1_aussen) 1 = (L.L.cp_schluessel_trans) ! && (L.L.engine_injection_on) ! && (L.L.door_0) 0 > &&
{if}
1 (S.L.door_1_aussen_licht)
{endif}
(L.L.cp_schluessel_trans) (L.L.engine_injection_on) || (L.L.door_1_aussen) 1 = &&
{if}
0 (S.L.door_1_aussen_licht) (S.L.door_1_aussen)
{endif}
' Innenlicht wenn Tuer von aussen geschlossen wurde
(L.L.door_1_aussen) -1 = (L.L.cp_schluessel_trans) ! && (L.L.engine_injection_on) ! && (L.L.door_0) 0 = &&
{if}
1 (S.L.door_1_aussen_licht)
(L.L.door_1_aussen_licht_zeit) 0 =
{if}
(L.L.globaltimer) (S.L.door_1_aussen_licht_zeit)
{endif}
(L.L.globaltimer) (L.L.door_1_aussen_licht_zeit) (C.L.door1_aussen_licht) + >
{if}
0 (S.L.door_1_aussen_licht_zeit) (S.L.door_1_aussen_licht) (S.L.door_1_aussen)
{endif}
{endif}
(L.L.elec_busbar_main) (L.L.engine_injection_on) || (L.L.door_1_aussen) -1 > ||
{if}
0 (S.L.door_1_aussen_licht_zeit)
{endif}
(L.L.door_oberlicht2_lichtreq)
(L.L.elec_busbar_main) && (L.L.lights_stand) && (L.L.elec_failure_general) ! &&
(S.L.door_oberlicht2)
(L.L.door_oberlicht3_lichtreq)
(L.L.elec_busbar_main) && (L.L.lights_stand) && (L.L.elec_failure_general) ! &&
(S.L.door_oberlicht3)
(L.L.door_oberlicht4_lichtreq)
(L.L.elec_busbar_main) && (L.L.lights_stand) && (L.L.elec_failure_general) ! &&
(S.L.door_oberlicht4)
(L.L.door_oberlicht5_lichtreq)
(L.L.elec_busbar_main) && (L.L.lights_stand) && (L.L.elec_failure_general) ! &&
(S.L.door_oberlicht5)
(M.L.lights_AI)
(M.L.lights_runblinkgeber)
(L.L.brake) 0.1 >
(L.L.elec_failure_general) ! &&
(L.L.elec_busbar_main) &&
(S.L.lights_brems)
(L.L.lights_sw_blinker) 1 = (L.L.lights_blinker_l) (L.L.lights_blinker_r) ! && ||
(L.L.elec_busbar_main) (C.L.elec_busbar_Vmin) > && (L.L.elec_failure_general) ! &&
(L.L.lights_sw_warnblinker) (L.L.lights_blinker_l) || ||
{if}
(L.L.lights_blinkgeber) (S.L.lights_blinker_l)
{else}
0 (S.L.lights_blinker_l)
{endif}
(L.L.lights_sw_blinker) 2 = (L.L.lights_blinker_r) (L.L.lights_blinker_l) ! && ||
(L.L.elec_busbar_main) (C.L.elec_busbar_Vmin) > && (L.L.elec_failure_general) ! &&
(L.L.lights_sw_warnblinker) (L.L.lights_blinker_r) || ||
{if}
(L.L.lights_blinkgeber) (S.L.lights_blinker_r)
{else}
0 (S.L.lights_blinker_r)
{endif}Code: cockpit.osc
' Lichtdrehschalter
{trigger:cp_lichtschalter_mov_drag}
(L.S.mouse_y) abs (L.S.mouse_x) abs >
{if}
' Translation
(L.S.mouse_y) 150 / (L.L.vdv_lichtschalter_trans) + 0 max 1 min (S.L.vdv_lichtschalter_trans) s0
l0 0.25 <
{if}
(L.L.vdv_lichtschalter_trans_mode) 0 > {if} (T.L.ev_lichtdrehschalter_zieh) {endif}
0 (S.L.vdv_lichtschalter_trans_mode) (S.L.cp_nebel_targeton) (S.L.cp_taster_nebelschluss_target)
{endif}
l0 0.25 >= l0 0.75 < &&
{if}
(L.L.vdv_lichtschalter_trans_mode) 0.5 = ! {if} (T.L.ev_lichtdrehschalter_zieh) {endif}
0 (S.L.cp_taster_nebelschluss_target)
0.5 (S.L.vdv_lichtschalter_trans_mode)
1 (S.L.cp_nebel_targeton)
{endif}
l0 0.75 >
{if}
(L.L.vdv_lichtschalter_trans_mode) 1 < {if} (T.L.ev_lichtdrehschalter_zieh) {endif}
1 (S.L.vdv_lichtschalter_trans_mode) (S.L.cp_nebel_targeton) (S.L.cp_taster_nebelschluss_target)
{endif}
{else}
' Rotation
(L.S.mouse_x) 70 / (L.L.vdv_lichtschalter_rot) + -0.5 max 1 min (S.L.vdv_lichtschalter_rot) s0
l0 -0.25 <
{if}
(L.L.lights_mode) 3 = !
{if}
(T.L.ev_lichtdrehschalter_dreh)
{endif}
-0.5 (S.L.vdv_lichtschalter_rot_mode) 3 (S.L.lights_mode)
{endif}
l0 0.25 < l0 -0.25 > &&
{if}
(L.L.lights_mode) 0 = !
{if}
(T.L.ev_lichtdrehschalter_aus)
{endif}
0 (S.L.vdv_lichtschalter_rot_mode) (S.L.lights_mode)
{endif}
l0 0.25 >= l0 0.75 < &&
{if}
(L.L.lights_mode) 1 = !
{if}
(T.L.ev_lichtdrehschalter_dreh)
{endif}
0.5 (S.L.vdv_lichtschalter_rot_mode)
1 (S.L.lights_mode)
{endif}
l0 0.75 >
{if}
(L.L.lights_mode) 2 = !
{if}
(T.L.ev_lichtdrehschalter_an)
{endif}
1 (S.L.vdv_lichtschalter_rot_mode)
2 (S.L.lights_mode)
{endif}
{endif}
{end}
{trigger:cp_lichtschalter_mov_drag_off}
' Einrasten
(L.L.vdv_lichtschalter_trans_mode) (S.L.vdv_lichtschalter_trans)
(L.L.vdv_lichtschalter_rot_mode) (S.L.vdv_lichtschalter_rot)
{end}Alle nötigen Constfile- und Varlisteinträge habe ich vorgenommen.
Ob das Abbiegelicht funktioniert kann ich noch nicht sagen, da ich bisher keine Spotlights dafür eingetragen habe. Erst möchte ich mal diese Baustelle fertig haben.
Liebe Grüße
Schrotti
